topic How to find the number of Sundays between two dates? in SAS Studio

How to find the number of Sundays between two dates?

alilacey0 — Tue, 26 Sep 2017 23:48:03 GMT

Using appropriate SAS DATE functions and maybe PROC FREQ, find a frequency table containing the number of Sundays (1), Mondays (2), ...., Saturdays (7) in the year 2017. You can enter your data/dates in any format you want.

Re: How to find the number of Sundays between two dates?

mkeintz — Tue, 26 Sep 2017 23:55:52 GMT

Homework, eh?

Re: How to find the number of Sundays between two dates?

Quentin — Wed, 27 Sep 2017 00:20:08 GMT

I think homework questions are fine. But as with any other question, it's important for you to two show what code you have tried, and describe how your code failed (errors in the log? incorrect results?) By posting your code, people can identify the error your made and help you understand the error (and correct it). By posting your code, you help people help you.

Re: How to find the number of Sundays between two dates?

alilacey0 — Wed, 27 Sep 2017 03:25:54 GMT

this is what I have so far, but we are having troubles getting the days of the week for 2017

I attached some of our results as well

(this does not run)

data dates;
do i=1 to 365;
Sundays = intck('weekday', '01Jan2017'd, '31Dec2017'd);
day = weekday(week);
run;

title "Number of Each Day of the Week in 2017";
proc print data == dates noobs;
var week Day -- Year;
run;

(this does run but not able to get any further, results are attached)

data days;

do i=0 to 365;

Day = intck('week', '01Jan2017'd, '31Dec2017'd);

end;

run;

title "Listing of Days of the Week for 2017";

proc print data=days noob;

run;

Re: How to find the number of Sundays between two dates?

error_prone — Wed, 27 Sep 2017 05:26:18 GMT

Does the first data-step what you expected? There should be at least notes about missing values in the log.

The following untested code (send from my mobile phone) should create a dataset to start with:
data dates;
do date = "1Jan2017"d to "31Dec2017"d;
dow = weekday(date);
output;
end;
run;

Now have a look a the documentation of proc freq ... the task should be easy to solve.

Re: How to find the number of Sundays between two dates?

ChrisBrooks — Wed, 27 Sep 2017 08:16:33 GMT

In the interests of full disclosure (and not wanting to commit plagiarism) I found this answer on stackoverflow https://stackoverflow.com/questions/40676721/number-of-sundays-between-two-dates

data _null_;
	format a b date9.;
	a='01 nov 2016'd;
	b='18 nov 2016'd;
	Sundays = intck('weekday234567w',a,b);
	put _all_;
run;

Re: How to find the number of Sundays between two dates?

mkeintz — Wed, 27 Sep 2017 15:50:34 GMT

The INTCK('week',from_date,to_date) will count the number of saturday/sunday boundaries crossed between from_date through to_date.

So consider;

n_sun2017=intck('week','31dec2016'd,'31dec2017'd);

or equivalently use the "week.1" interval descriptor.

n_sun2017=intck('week.1','31dec2016'd,'31dec2017'd);

Number of Monday's? Then you need to count the number of sun/mon boundaries, so use the "week.2" interval descriptor:

n_mon2017=intck('week.2','31dec2016'd,'31dec2017'd);

Re: How to find the number of Sundays between two dates?

ShiroAmada — Thu, 28 Sep 2017 08:50:10 GMT

Try this.....

data HAVE;
  start='01jan2016'd; end='31dec2016'd; output;
  start='01jan2017'd; end='31dec2017'd; output;
run;

data want;
  set have;
 sunday=0;
do i=start to end;
  sunday=ifn(weekday(i)=1, sum(sunday,1),sunday);
  retain sunday;
end;
run;

Hope this helps.

Re: How to find the number of Sundays between two dates?

mkeintz — Fri, 29 Sep 2017 02:53:06 GMT

Just note that when using the INTCK function to count a particular day-of-week, the "from" date should be the day before the actual start of interval.

Consider '03jan2016'd and '10jan2016'd which are both Sunday, so for that date range you would want N_SUN=2. But

start='03jan2016'd;

end='10jan2016'd;

n_sun=intck('week.1',start,end) ==> 1 (not 2)

or identically
n_sun=intck('weekday234567w',start,end) = 1

so use

n_sun=intck('week.1',start-1,end)