topic Re: how to append different column within the same dataset in SAS Studio

how to append different column within the same dataset

miris — Fri, 16 Dec 2016 08:40:45 GMT

origin file

group weight01 weight02 weight03

A 1 2 3

A 4 5 6

B 7 8 9

B 6 5 4

I woul like to

group weight

A 1

A 4

B 7

B 6

A 2

A 5

B 8

B 5

A 3

A 6

B 9

B 4

Re: how to append different column within the same dataset

miris — Fri, 16 Dec 2016 08:58:38 GMT

I think I find the answer.

it is folowing logic

proc sql;
create table allvars as 
select var1 from dataset
union
select var2 from dataset
union
select var3 from dataset;
quit;

Re: how to append different column within the same dataset

Kurt_Bremser — Fri, 16 Dec 2016 09:08:07 GMT

Explicit method in a data step:

data want;
set have;
array weights {*} weight01-weight03;
do i = 1 to dim(weights);
  weight = weights{i};
  output;
end;
keep group weight;
run;

Re: how to append different column within the same dataset

Kurt_Bremser — Fri, 16 Dec 2016 09:11:50 GMT

@miris wrote:

I think I find the answer.

it is folowing logic
proc sql;
create table allvars as 
select var1 from dataset
union
select var2 from dataset
union
select var3 from dataset;
quit;

Correct version (giving exactly the output you initially posted):

proc sql;
create table allvars as 
select group, weight01 as weight from have
union all
select group, weight02 as weight from have
union all
select group, weight03 as weight from have;
quit;

Re: how to append different column within the same dataset

RW9 — Fri, 16 Dec 2016 10:09:58 GMT

Or simply:

data want;
  set have (rename=(weight01=weight))
      have (rename=(weight02=weight))
      have (rename=(weight03=weight));
run;