topic Re: Customise ODS PDF Table of Contents in SAS Studio

Customise ODS PDF Table of Contents

Springyboy — Fri, 05 May 2023 03:42:50 GMT

Hi everyone,

I am trying to customise my ODS PDF table of contents using an SGPlot. I am running SAS 3.3 so am unsure if this is supported.

Can someone please confirm whether this is possible for my version of SAS Studio?

E.g. the code below does not customise the table of contents from here https://support.sas.com/resources/papers/proceedings11/252-2011.pdf -

ods pdf file="display1.pdf";
proc print noobs data=sashelp.cars; run;
proc gchart data=sashelp.cars;
vbar type / sumvar=horsepower;
run;
quit;
ods pdf close;

But instead outputs:

the print procedure
print (1st node should be customised)
the gchart procedure
gchart (1st node should be customised)

in the table of contents instead of customising the first node as described in the training.

Thanks so much!

Re: Customise ODS PDF Table of Contents

yabwon — Fri, 05 May 2023 08:21:51 GMT

Try this:

ods html close;
ods pdf file="display1.pdf";

title;
title "Output from PRINT procedure";
ods proclabel "Output from PRINT procedure";
proc print noobs data=sashelp.cars contents="Output from PRINT procedure for sashelp.cars"; 
run;

title "A graph of horsepower";
ods proclabel "A graph of horsepower";
proc gchart data=sashelp.cars;
vbar type / sumvar=horsepower description="Output from GCHART procedure for Type in sashelp.cars";
run;
quit;
ods pdf close;
ods html;

and read about: ods proclabel, contents=, description=, etc.

Bart

Re: Customise ODS PDF Table of Contents

Springyboy — Sun, 07 May 2023 23:36:24 GMT

Thanks so much for that!

That works but only when I was running SAS in a fresh session or resetting it.

It turns out another piece of code I was running had the statement in it:

options nolabel;

Once I removed that then this code ran as intended.