topic Re: Maximum Variable in SAS Procedures

Maximum Variable

deleted_user — Wed, 06 Aug 2008 09:13:22 GMT

Hi

I have a list of 8 variables and want to find the largest variable for each record.
For example if my data looked like this:
Key age1 age2 age3 age4
001 0.5 0.6 0.7 0.3
002 0.8 1.7 1.2 4.6
I would like to create a variable that looks like this:
Key age1 age2 age3 age4 maxv
001 0.5 0.6 0.7 0.3 age3
002 0.8 1.7 1.2 4.6 age4

Anyone know how I could do this, or something similar?

Re: Maximum Variable

LinusH — Wed, 06 Aug 2008 11:38:08 GMT

Hi,
try the MAX-function (in a data step):

maxv = max(age1, age2, age3, age4); or in your specific case with a variable list:
maxv = max(of age1-age4);

Regards,
Linus

Re: Maximum Variable

sbb — Wed, 06 Aug 2008 12:52:03 GMT

One technique is to use a SAS macro variable to identify/track the age values, presuming the data sample you provided. Here's some SAS code that works.

Scott Barry
SBBWorks, Inc.

%let ages = age1 age2 age3 age4;
data _null_;
input Key $ &ages;
* use array to interrogate age# var list for max. ;
array _agevars (*) &ages ;
do i=1 to dim(_agevars);
if _agevars(i) gt _maxval then do;
drop _maxval;
* keep track of the max var-value thus far. ;
_maxval = _agevars(i);
* keep track of the var-name having max value thus far. ;
maxv = upcase(scan("&ages",i,' '));
end;
end;
putlog _all_;
datalines;
001 0.5 0.6 0.7 0.3
002 0.8 1.7 1.2 4.6
run;

Re: Maximum Variable

deleted_user — Wed, 06 Aug 2008 13:25:35 GMT

thanks Linus, this gave me the value of the maximum variable, whereas I was after the variable name, however I will definitely use this in the future!

Re: Maximum Variable

deleted_user — Wed, 06 Aug 2008 13:26:28 GMT

thank you Scott that worked perfectly

Re: Maximum Variable

deleted_user — Thu, 07 Aug 2008 03:01:04 GMT

you can use the function varname and varnum combine with macro to do that

Re: Maximum Variable

deleted_user — Thu, 07 Aug 2008 03:05:18 GMT

use these two function you do not need to know the variname, only do loop on the variable number, but be ware that you should use %sysfun in the macro enviroment

Re: Maximum Variable

Olivier — Thu, 07 Aug 2008 07:58:23 GMT

Hi.
What seems to me a simpler solution -- no macros needed, just use the VNAME function.
[pre]
data out (drop = i max_age) ;
set in ;
array ages age: ;
max_age=MAX(OF age:) ;
do i=1 TO DIM(ages) ;
if ages(i) = max_age then maxv=VNAME(ages(i)) ;
end ;
run ;
[/pre]
Regards,
Olivier

Re: Maximum Variable

sbb — Thu, 07 Aug 2008 13:08:19 GMT

Very clean, Olivier. The VNAME function had escaped me and so I used the macro variable (parsing) approach. Thanks for the great tip!

Regards,

Scott Barry
SBBWorks, Inc.