topic Re: Can't calculate horisontal difference in PROC REPORT in SAS Procedures

Can't calculate horisontal difference in PROC REPORT

Multipla99 — Wed, 12 Nov 2025 12:47:44 GMT

Can someone please help me and explain why I get the following messages when I run the code below?

NOTE: Variable Weight is uninitialized.
NOTE: Variable Height is uninitialized.

And why the column DIFF is empty in the result table?

proc report

data= SASHELP.CLASS;

column Sex Height Weight Diff;

define Sex / group

'Sex'

style(column)=

{just= l };

define Height / sum

'Height'

style(column)=

{just= l };

define Weight / sum

'Weight'

style(column)=

{just= l };

define Diff / computed 'Diff'

style(column)=

{just= r};

compute Diff;

Diff = Height - Weight;

endcomp;

compute before;

Sex='TOTALT';

endcomp;

rbreak before/ SUMMARIZE;

run;

Re: Can't calculate horisontal difference in PROC REPORT

Kathryn_SAS — Wed, 12 Nov 2025 13:05:41 GMT

You need to refer to the variables with their .statistic extension. Also to prevent the label for Sex from being truncated at the Break line, you need to change the length.

Revised code:

data class;
length sex $8;
set sashelp.class;
run;

proc report data= CLASS;
column Sex Height Weight Diff;
define Sex / group 'Sex'
style(column)={just= l }; 
define Height  / sum 'Height'
style(column)= {just= l }; 
define Weight / sum 'Weight'
style(column)= {just= l }; 
define  Diff / computed 'Diff'
style(column)= {just= r};  

compute Diff;
 Diff = Height.sum - Weight.sum;
endcomp;

compute before;
Sex='TOTALT';
endcomp;

rbreak before/ SUMMARIZE;
run;

Re: Can't calculate horisontal difference in PROC REPORT

Tom — Thu, 13 Nov 2025 15:50:32 GMT

PROC REPORT can create the longer variable.

proc report data= sashelp.CLASS;
column Sex Sex2 Height Weight Diff;
define Sex / group noprint;
define Sex2 /  group computed 'Sex' style(column)={just= l }; 
define Height  / sum 'Height' style(column)= {just= l }; 
define Weight / sum 'Weight' style(column)= {just= l }; 
define  Diff / computed 'Diff' style(column)= {just= r};  

compute sex2 / character length=8;
  sex2=sex;
endcomp;

compute Diff;
 Diff = Height.sum - Weight.sum;
endcomp;

compute before;
Sex2='TOTAL';
endcomp;

rbreak before/ SUMMARIZE;
run;