PROC FREQ Binomial 95%CI with ratio=0% (e.g., 0 out of 4)

paulrutti — Wed, 11 Dec 2024 19:28:46 GMT

Have category variable and within each category, a binary (0,1) variable. Need 95% CI for all categories. But if ratio is 0%, there is nothing in the output file, so how do I find the upper limit 95% CI using PROC FREQ (or alternate procedure).

Re: PROC FREQ Binomial 95%CI with ratio=0% (e.g., 0 out of 4)

FreelanceReinh — Wed, 11 Dec 2024 20:33:06 GMT

Hello @paulrutti and welcome to the SAS Support Communities!

The ZEROS option of the WEIGHT statement is often useful in this situation. Does the example below help you?

/* Create sample data for demonstration */

data have;
do category='A', 'B', 'C';
  do _iorc_=1 to 9;
    _n_+1;
    binvar=(_n_<17);
    output;
  end;
end;
run;

/* Create intermediate dataset including combinations with zero frequencies */

proc freq data=have noprint;
tables category*binvar / sparse out=cnt;
run;

/* Compute confidence intervals for the proportion of BINVAR=1 in each category */

proc freq data=cnt;
by category;
weight count / zeros;
tables binvar / binomial(level='1');
run;

topic PROC FREQ Binomial 95%CI with ratio=0% (e.g., 0 out of 4) in SAS Procedures

PROC FREQ Binomial 95%CI with ratio=0% (e.g., 0 out of 4)

Re: PROC FREQ Binomial 95%CI with ratio=0% (e.g., 0 out of 4)