topic Re: Longitudinal study - how to plot the outcome with CI against time in SAS Procedures

Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Sun, 14 Jul 2024 03:14:36 GMT

Hello, everyone

Today I read this research paper "Plozasiran (ARO-APOC3) for Severe Hypertriglyceridemia
The SHASTA-2 Randomized Clinical Trial" (doi:10.1001/jamacardio.2024.0959).

I am very interested in the line of Figure 2. According to my understanding, the model used in this research probably is a linear mixed model, and follow-up time is an independent factor. What I am not sure is how the author estimated the confidence interval of the outcomes in Figure 2? Using the linear mixed model? Or other methods?

Please let me know your ideas. Thank you.

Figure 2

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Sun, 14 Jul 2024 03:49:39 GMT

Check @Rick_SAS blogs:

https://blogs.sas.com/content/iml/2016/06/22/sas-effectplot-statement.html

data have;
call streaminit(123);
do subject=1 to 100;
 do time=1 to 10;
   sex=ifc(rand('bern',0.4),'F','M');
   weight=rand('normal',4,100);
   height=rand('normal',0,2);
   output;
 end;
end;
run;

proc mixed data=have;
class  subject sex time;
model weight=height sex time/s;
random int/subject=subject;
repeated time/subject=subject ;
store out=mixedmodel;
run;
proc plm source=mixedmodel;
   effectplot INTERACTION(x=time  sliceby=sex /*plotby=CigsPerDay*/ )/limits connect;
run;

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Sat, 27 Jul 2024 06:10:53 GMT

@Ksharp Hello, Ksharp. Thank you for your answer. Would you mind if you tell me whether it is appropriate to use only one of the random and repeated statements?

I think either the random or repeated statement can adjust the intra-individual relationship.

Tom

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Sat, 27 Jul 2024 06:17:45 GMT

Yes. You can. But you have to have TIME variable in MODEL to plot the interaction graph.

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Mon, 19 Aug 2024 10:36:03 GMT

One more thing, I am thinking of what the codes should be if the response variable is not continuous (e.g., weight) but binary (e.g., event present). In this case, individuals are repeatedly measured to collect their status of the binary response variable and we would like to have a similar series graph. The x-axis remains the sequence of the repeated measurement, but the y-axis represent the risk (i.e., proportion) for the event to occur, along with its confidence interval.

Many thanks.

Tom

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Tue, 20 Aug 2024 02:03:55 GMT

If your Y variable is a binary variable,you could use PROC GLIMMIX instead of PROC MIXED.

data have;
call streaminit(123);
do subject=1 to 10;
 do time=1 to 5;
   y=rand('bern',0.8);
   sex=ifc(rand('bern',0.4),'F','M');
   weight=rand('normal',4,100);
   height=rand('normal',0,2);
   output;
 end;
end;
run;

/*Take TIME as R side random effect */
proc glimmix data=have;
class  subject sex time;
model y=height sex time/solution dist=binary ;
random int/subject=subject;
random time/subject=subject residual;
store out=mixedmodel;
run;
proc plm source=mixedmodel;
   effectplot INTERACTION(x=time  sliceby=sex /*plotby=CigsPerDay*/ )/limits connect;
run;



/*Take TIME as G side random effect */
proc glimmix data=have;
class  subject sex ;
model y=height sex time/solution dist=binary ;
random int time/subject=subject;
store out=mixedmodel;
run;
proc plm source=mixedmodel;
   effectplot slicefit(x=time  sliceby=sex /*plotby=CigsPerDay*/ )/limits ;
run;

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 21 Aug 2024 05:17:55 GMT

Thank you for your information.

What will happen if we treat the variable of time as a category variable in the class statement? Here, the time we use is not a continuous variable. Instead, it's a proxy of the number of a series of repeated measurements. For example, we monitor the individuals and we test their blood several times during the following period. Thx.

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Wed, 21 Aug 2024 06:05:37 GMT

Check my code
/*Take TIME as R side random effect */
..........

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 21 Aug 2024 06:29:01 GMT

NOTE: An R-side variance component is confounded with the profiled variance.
NOTE: The GLIMMIX procedure is modeling the probability that inr_attain='1'.
NOTE: Did not converge.
NOTE: The GLIMMIX procedure deleted the model item store WORK.MIXEDMODEL because of incomplete information for a subsequent
analysis.

Problem with the raw data?

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Wed, 21 Aug 2024 07:35:57 GMT

Yes.
NOTE: Did not converge.
it stands for your model is not right or trust .
Change your model syntax or Check the data.

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 11 Sep 2024 12:34:39 GMT

proc glimmix data = highlow_1;
class  Patient_ID Gender;
model inr_attain(event = '1') = measure Gender / dist = binary solution;
random intercept / subject = Patient_ID;
*random measure / subject = Patient_ID residual;
store out = mixedmodel;
run;

proc plm source = mixedmodel;
effectplot slicefit(x = measure sliceby = Gender) / limits;
run;

This is the measure as G side random effect and it produces the graph.

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 11 Sep 2024 12:38:00 GMT

But we would like to treat the variable of measure as a class variable.

proc glimmix data = highlow_1;
class  Patient_ID Gender measure;
model inr_attain(event = '1') = measure Gender / dist = binary solution;
random intercept / subject = Patient_ID;
random measure / subject = Patient_ID residual;
store out = mixedmodel;
run;

proc plm source = mixedmodel;
effectplot interaction(x = measure sliceby = Gender) / limits connect;
run;

And this produced the "Did not converge." outcome.

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 11 Sep 2024 12:47:50 GMT

The fix should be this,

proc glimmix data = highlow_1;
class  Patient_ID Gender measure;
model inr_attain(event = '1') = measure Gender / dist = binary solution;
*random intercept / subject = Patient_ID;
random measure / subject = Patient_ID residual;
store out = mixedmodel;
run;

proc plm source = mixedmodel;
effectplot interaction(x = measure sliceby = Gender) / limits connect;
run;

The graph

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Thu, 12 Sep 2024 00:35:07 GMT

Yes.
That what my code wrote for R side random effect (take variable of measure as a class variable.).

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Mon, 30 Sep 2024 14:52:27 GMT

Thanks for the update and I have additional questions.

What is the function of this line?

*random intercept / subject = Patient_ID;

With this line un-asterisked, I had the error:

NOTE: An R-side variance component is confounded with the profiled variance.
NOTE: The GLIMMIX procedure is modeling the probability that inr_attain='1'.
NOTE: Did not converge.
NOTE: The GLIMMIX procedure deleted the model item store WORK.MIXEDMODEL because of incomplete information for a subsequent
analysis.

In addition, in proc mixed, the random and repeated statements are used to represent between- and within-individual differences. What about the proc glimmix?

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Tue, 01 Oct 2024 01:42:56 GMT

That is G-Side random effect with SUBJECT_ID variable.

If you can get model convergency you need some skill to adjust parameters of model . Check this:
https://support.sas.com/resources/papers/proceedings12/332-2012.pdf

in proc mixed, the random and repeated statements model G-Side and R-Side random effect separatedly.
Correspond to PROC GLIMMIX ,it should be:
G_Side effect:
random intercept / subject = Patient_ID;

R_Side effect:
random visit/ subject = Patient_ID residal ;
or
random _residual_/ subject = Patient_ID;

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Thu, 24 Oct 2024 12:08:10 GMT

Hello, @Ksharp

I spent a couple of weeks learning the general linear mixed model. The model is in the form of the formula in the screenshot.

We can use the maximum likelihood method or matrix of variance-covariance to solve the point and interval estimation of the regression coefficients. What I don't understand is: What is the difference between the G- and R-side models? Both belong to the general linear mixed model, so they have the same model formula.

Re: Longitudinal study - how to plot the outcome with CI against time

Ksharp — Fri, 25 Oct 2024 01:32:32 GMT

Ou. That is a large topic. I think @lvm @SteveDenham could give you more details about it.
G-side random effect is for estimate coefficient.
For example : if you take SEX as fixed and random effect,
then the actually coefficient = coefficient (of fixed effect) +coefficient (of random effect) .
here coefficient (of fixed effect) is the same for Both Male and Female,
while coefficient (of random effect) is different for Male and Female.

The horizontal level/direction has random coefficient.

R-side random is design for RESIDUAL term.
For examle : if you take VISIT as random effect ,the residual from each VISIT is diffent/random.

The vertical level/direction has random coefficient.

Check resources for more info:
https://stats.oarc.ucla.edu/other/mult-pkg/introduction-to-generalized-linear-mixed-models/
https://support.sas.com/kb/37/109.html
https://support.sas.com/kb/37/110.html
https://blogs.sas.com/content/iml/2019/12/03/longitudinal-data-response-profile-model.html
https://blogs.sas.com/content/iml/2019/12/05/longitudinal-data-mixed-model.html

Re: Longitudinal study - how to plot the outcome with CI against time

SteveDenham — Wed, 30 Oct 2024 12:42:20 GMT

I realize this sort of jumping into the middle but I would suggest looking at the output file, especially the iteration history. If the history stops at 20 iterations with no other messages, then you have run up against the default maximum. If the history keeps rolling along and eventually has some other message, then there are some things to try. For a first attempt, I would suggest adding the following NLOPTIONS statement:

nloptions maxiter=1000 tech=nrridg;

For R-side models and a binary distribution, the ridged Newton-Raphson method often works better than the default quasi-Newton (QUANEW).

Good luck.

SteveDenham

Re: Longitudinal study - how to plot the outcome with CI against time

TomHsiung — Wed, 30 Oct 2024 13:21:22 GMT

Thanks for the suggestion, sir. But I think I must first understand the G- and R-side models first. I know understand the formula of a general linear mixed model but the textbook I read does not discuss this topic in detail.