topic Re: Proc report, go to line when i want in a single text report in SAS Procedures

Proc report, go to line when i want in a single text report

Mathassens — Fri, 23 Feb 2024 15:25:50 GMT

Hello,

I 'm trying to go to line when i wish with a simple proc report (to display some text at the end of a page in a pdf report).

Could you help me please ?

This is my code: what i have

data notes;
order_row=1;
text="Le graphique ci-dessus met en relation le poids des prestations ( taille des bulles) , le coût moyen par effectif en abscisse et la fréquence en ordonnée pour chaque poste de soins.* Plus la bulle est grande, plus le poids des prestations est élevé.*Plus le coût moyen est élevé, moins la fréquence est élevée (exemple: dentaire).";
output;
run;

proc report data=notes noheader nowd split="*"
style(REPORT)={frame=void vjust=middle }
style(COLUMN)={font=(Helvetica) cellwidth=1500 just=center vjust=center foreground=black background=white font_size=10 pt
font_weight=bold just=left bordertopcolor=&couleur_1 borderbottomcolor=&couleur_1 borderrightcolor=&couleur_1 borderleftcolor=&couleur_1};
column order_row text ;
DEFINE order_row / noprint ;
DEFINE text / left ;

run;

Re: Proc report, go to line when i want in a single text report

Mathassens — Fri, 23 Feb 2024 15:28:44 GMT

Sorry, i make a mistake when i post my post 😞

In fact, i want to go line after each . in the text

I try to do it whith a split but it's not OK 😞

Re: Proc report, go to line when i want in a single text report

sbxkoenk — Sat, 24 Feb 2024 13:27:10 GMT

As PROC REPORT is not a statistical procedure ... I moved this to "SAS Procedures" - board under Programming header.

Re: Proc report, go to line when i want in a single text report

sbxkoenk — Sat, 24 Feb 2024 13:38:23 GMT

Use the data step to do the split.
Then use PROC REPORT (the splitting character in PROC REPORT is for headers).

Make dataset notes1 and character text1 and report on these.

data notes1(drop=i cp);
 LENGTH text1 $330;
 set notes;
 cp = countc(text, '.');
 put cp=;
 do i = 1 to cp;
  text1 = scan(text, i, '.');
  output;
 end;
run;

Koen

Re: Proc report, go to line when i want in a single text report

Ksharp — Sun, 25 Feb 2024 09:56:08 GMT

You can't have circle corner I guess. But you can use ~n to break a line.

data notes;
order_row=1;
text="Le graphique ci-dessus met en relation le poids des prestations ( taille des bulles) , le coût moyen par effectif en abscisse et la fréquence en ordonnée pour chaque poste de soins. ~n  * Plus la bulle est grande, plus le poids des prestations est élevé. ~n *Plus le coût moyen est élevé, moins la fréquence est élevée (exemple: dentaire).";
output;
run;

ods escapechar='~';
ods pdf file='c:\temp\temp.pdf';

proc report data=notes noheader nowd split="*"
style(REPORT)={frame=void vjust=middle }
style(COLUMN)={font=(Helvetica) cellwidth=1500 just=center vjust=center foreground=black background=white font_size=10 pt
font_weight=bold just=left bordertopcolor=&couleur_1 borderbottomcolor=&couleur_1 borderrightcolor=&couleur_1 borderleftcolor=&couleur_1};
column order_row text ;
DEFINE order_row / noprint ;
DEFINE text / left ;

run;
ods pdf close;

Re: Proc report, go to line when i want in a single text report

Mathassens — Mon, 26 Feb 2024 09:57:42 GMT

Thanks you for yours answers.