topic Re: How to calculate cumulative variable by group? in SAS Procedures

How to calculate cumulative variable by group?

deleted_user — Wed, 23 Dec 2009 02:00:52 GMT

DATA Temp;
INPUT Group Salary;
CARDS;
1 5000
1 6000
1 2100
2 1110
2 5000
2 5000
3 5000
3 5000
;
RUN;

Data Temp1;
set Temp;
Cum_salary + Salary;
RUN;

But how can i calculate cumulative salary by group?

Re: How to calculate cumulative variable by group?

sbb — Wed, 23 Dec 2009 02:18:07 GMT

Have you looked at PROC FREQ with the OUT= option?

Scott Barry
SBBWorks, Inc.

Recommended Google advanced search argument:

proc freq cumulative frequency site:sas.com

Re: How to calculate cumulative variable by group?

deleted_user — Wed, 23 Dec 2009 07:36:08 GMT

Data Temp1;
set Temp;
by group;
if first.Group then Cum_salary=Salary;
else Cum_salary + Salary;
RUN;

Re: How to calculate cumulative variable by group?

deleted_user — Wed, 23 Dec 2009 08:56:13 GMT

Thanks~

But if set two group?
It seems no effect......please~

DATA Temp;
INPUT Group1 Group2 Salary;
CARDS;
1 A 5000
1 A 6000
1 B 2100
2 A 1110
2 B 5000
2 B 5000
3 A 5000
3 A 5000
;
RUN;

Data Temp1;
set Temp;
by Group1 Group2;
if first.Group1 & first.Group2 then cum_salary= salary;
else cum_salary+ salary;
run;

Re: How to calculate cumulative variable by group?

deleted_user — Wed, 23 Dec 2009 09:08:04 GMT

try this.

DATA Temp;
INPUT Group1 Group2 $ Salary;
CARDS;
1 A 5000
1 A 6000
1 B 2100
2 A 1110
2 B 5000
2 B 5000
3 A 5000
3 A 5000
;
RUN;

proc sort data=temp;
by Group1 Group2;
run;

Data Temp1;
set Temp;
by Group1 Group2;
if first.Group2 then cum_salary= salary;
else cum_salary+ salary;
run;

Re: How to calculate cumulative variable by group?

deleted_user — Wed, 23 Dec 2009 09:16:16 GMT

THANKS~