topic Re: proc report use indent format in compute statement in SAS Procedures

proc report use indent format in compute statement

whymath — Tue, 09 Aug 2022 04:05:38 GMT

I want to custom indentation in compute statement of proc report. My code is like this:

proc sort data=sashelp.class out=class;
  by sex;
run;

proc format;
  value $indsex
  'M'=20
  'F'=40
  ;
run;

proc report data=class nowd;
  column _all_;
  define sex  /noprint order order=data;
  compute before sex/style={indent=$indsex.};
    line @1 sex $;
  endcomp;
run;

It doesn't work.

I know there is if statement can be used in compute block to solve this, but why indent=$format. just doesn't work?

Thanks for any hints.

Re: proc report use indent format in compute statement

Kurt_Bremser — Tue, 09 Aug 2022 10:08:01 GMT

The stuff coming after the slash in the COMPUTE statement has declarative character and is evaluated when the procedure is prepared for execution. But you can make the position in the LINE statement dynamic (similar to a PUT statement in a data step), but you need to create an informat to get a numeric value first:

proc format;
  invalue indsex
  'M'=20
  'F'=40
  ;
run;

proc report data=class nowd;
  column _all_;
  define sex  /noprint order order=data;
  compute before sex;
    __tmp = input(sex,indsex.);
    line @__tmp sex $;
  endcomp;
run;