ODS select LSMeans adds duplicate observations. How to correct?

MaryA_Marion — Mon, 22 Nov 2021 02:20:47 GMT

This has to do with proc mixed difference of LSMeans and LSMeans tables.

Here is my code:

%let data = sashelp.cars;
%let depvar = mpg_city;
%let indvar = origin;
ods trace on;
proc mixed data=&data method=type3;
class &indvar;
model &depvar=&indvar / solution;
lsmeans &indvar / pdiff alpha=.05 cl; 
lsmeans &indvar / pdiff adjust=BON alpha=0.05 cl;
lsmeans &indvar / pdiff adjust=DUNNETT alpha=0.05 cl;
lsmeans &indvar / pdiff adjust=GT2 alpha=.05 cl; *Sidaks SMM;
lsmeans &indvar / pdiff adjust=SCHEFFE alpha=0.05 cl;
lsmeans &indvar / diff adjust=SIDAK alpha=.05 cl;
lsmeans &indvar / pdiff adjust=simulate(seed=4938371 report) alpha=.05 cl;
lsmeans &indvar / pdiff adjust=TUKEY alpha=0.05 cl;
run; quit; title;

Every run of lsmeans causes LS means to be added to Least Squares Means Table.
My attempt seen below is resulting in Differences of LSmeans table not being output.
ods select ModelInfo ClassLevels Dimensions Nobs Type3 CovParms FitStatistics 
    SolutionF Tests3 LSMeans where = (_path_ ? 'Step1');

Can you help? Thank you.

Re: ODS select LSMeans adds duplicate observations. How to correct?

FreelanceReinh — Mon, 22 Nov 2021 10:55:24 GMT

Hello @MaryA_Marion,

You can create the "Differences of Least Squares Means" table in a separate PROC MIXED step. With suitable preparations, partly depending on your ODS destination, the output will look (almost) like it was created by a single PROC MIXED step.

Example with ODS HTML:

%let data = sashelp.cars;
%let depvar = mpg_city;
%let indvar = origin;

ods html file='C:\Temp\mixed_model.html' options(pagebreak='no');
ods select ModelInfo ClassLevels Dimensions Nobs Type3 CovParms FitStatistics 
           SolutionF Tests3 LSMeans;

proc mixed data=&data method=type3;
class &indvar;
model &depvar=&indvar / solution;
lsmeans &indvar / alpha=.05 cl; 
run;

title;
ods noproctitle;
ods select Diffs;

proc mixed data=&data;
class &indvar;
model &depvar=&indvar;
lsmeans &indvar / pdiff alpha=.05 cl; 
lsmeans &indvar / pdiff adjust=BON alpha=0.05 cl;
lsmeans &indvar / pdiff adjust=DUNNETT alpha=0.05 cl;
lsmeans &indvar / pdiff adjust=GT2 alpha=.05 cl; *Sidaks SMM;
lsmeans &indvar / pdiff adjust=SCHEFFE alpha=0.05 cl;
lsmeans &indvar / pdiff adjust=SIDAK alpha=.05 cl;
lsmeans &indvar / pdiff adjust=simulate(seed=4938371 report) alpha=.05 cl;
lsmeans &indvar / pdiff adjust=TUKEY alpha=0.05 cl;
run;

ods html close;

title 'The SAS System';
ods proctitle;

For LISTING output you may want to add

options nonumber nodate formdlim=' ';

before the second PROC MIXED step and

options number date formdlim='';

after it (if these are the option settings that you want to restore).

topic ODS select LSMeans adds duplicate observations. How to correct? in SAS Procedures

ODS select LSMeans adds duplicate observations. How to correct?

Re: ODS select LSMeans adds duplicate observations. How to correct?