topic Re: %DO, Iterative Statement in SAS Procedures

%DO, Iterative Statement

raivester — Mon, 13 Jul 2020 18:28:22 GMT

Hello, below is a sample of the code I'm trying to run; however, I keep getting errors messages: "Apparent symbolic reference I_TEMP not resolved" and about the & symbol not being recognized and thus being ignored. Any ideas what is going on here?

%macro create(years);
	%do i=2017 %to &years;

		/*Comment.*/
		data merge_&i_temp;
		 	set annual.data_ab_&i;
		  	keep year state state_code;
		  	year = &i;
		  	if stcode = "01" then state = "AL" ;
			if stcode = "02" then state = "AK" ;
	
		  	length state_code $43;

		  	array array var1 var2 var3;

		  	do a=1 to 3;
			  	state_code = array[a];
				output;
		  	end;

		 run;
	 
		 /*Comment.*/
		 data merge_&i_temp;
		 	set merge_&i_temp;
			if state_code NE " ";
		 run;

		/*More data and proc steps.*/

	%end;

%mend create;

%create(2019)

Re: %DO, Iterative Statement

ketpt42 — Mon, 13 Jul 2020 18:35:45 GMT

The macro processor is looking for the macro variable %i_temp, which likely does not exist. You need to separate the macro variable &i from the rest of the text by using a period.
Instead of this:

merge_&i_temp;

You should have this:

merge_&i._temp;

You'll need to replace all instances of &i with &i.

Re: %DO, Iterative Statement

PaigeMiller — Mon, 13 Jul 2020 18:35:15 GMT

The idea presented in your earlier thread, @raivester , is to not use data sets by year, and then you don't need macros, and then you don't run into macro errors.

You could combine all of the annual data sets into one large data set covering multiple years, and all of these coding difficulties caused by macros are gone.

Re: %DO, Iterative Statement

Reeza — Mon, 13 Jul 2020 19:08:13 GMT

Your second data step is unnecessary.

Re: %DO, Iterative Statement

raivester — Mon, 13 Jul 2020 19:15:50 GMT

Thank you! This was exactly what I needed. Originally I named the data set merge_&i and not merge_&i_temp. Apparently not having the period did not matter in the first case since &i ended the data set name.

Re: %DO, Iterative Statement

Tom — Mon, 13 Jul 2020 19:19:47 GMT

You need to use period to let macro processor know where you macro variable name ends.

But if you had put the numeric suffix at the END of the name instead of trying to embed it in the middle it wouldn't have mattered.

merge_temp_&i

Plus then you can use a range of dataset names.

data want;
  set merge_temp_2017 - merge_temp_&years ;
run;