topic Assign a number for each group in SAS Procedures

Assign a number for each group

HappySASUE — Fri, 22 Nov 2019 17:27:41 GMT

Hi, Can anybody tell me how to add a series number for every 70 subjects, for 14000 subjects. For example

subject series

00001 1

00002 1

00003 1

...

00071 2

00072 2

...

000141 3

13931 200

...

14000 200

Thanks!

Re: Assign a number for each group

Tom — Fri, 22 Nov 2019 17:40:33 GMT

Are you generating that data?

data want;
  do series=1 to 200;
    do _n_=1 to 70 ;
      subject_num+1;
      subject=put(subject_num,z5.);
      output;
    end;
  end;
run;

Or generating SERIES for an existing dataset.

You can either count them yourself by placing the SET/OUTPUT statements inside a DO loop.

data want;
  series+1;
  do _n_=1 to 70;
    set have ;
    output;
  end;
run;

or convert the observation counter. So 1-70 is mapped to 1 and 71-140 is mapped to 2, etc.

data want;
  set have ;
  series = 1+int((_n_-1)/70);
run;

Re: Assign a number for each group

r_behata — Fri, 22 Nov 2019 17:41:47 GMT

data have;
	do _n_=1 to 14000;
		subect=put(_n_,z5.); output;
	end;
run;


data want;
	set have;
	retain series 1;

	_iorc_=mod(_n_,70);

	if _iorc_ eq 0 then series +1;
	
run;

Re: Assign a number for each group

mkeintz — Fri, 22 Nov 2019 18:59:14 GMT

If program minimization is the goal:

data want;
  set have;
  series=  ceil(_n_/70);
run;

This technique can also be used when reading (and keeping 100%) of raw data:

data want;
  infile 'c:\temp\mydatalines.txt';
  input a b c … ;
  series=ceil(_n_/70);
run;

Re: Assign a number for each group

HappySASUE — Sat, 23 Nov 2019 02:12:57 GMT

Thank you so much! Really helpful.