topic Re: Loop or Array? in SAS Procedures

Loop or Array?

BaileyY — Sat, 21 Sep 2019 21:47:47 GMT

Hi.

Can anyone help me write a loop that will run through a dataset and for each row for each ID - stop at column variable 'Summer' and take the information in that column and put into a new column called 'New_String'. Each running loop would input that new information value from 'Summer' and add onto the next byte under the new column. Example below:

ID #2516 has three records in this dataset. Each record has a different value in column 'Summer'. Notice in column 'New_String' each of those values are concatenated together to create value 'ABD'

Is this doable? Thank you for any help!

Data:
ID	Summer	Price
2516	A	269
1678	A	240
20982	B	125
2516	B	452
20982	A	315
2516	D	804
20982	D	804
20982	A	200

WANT:
ID	NEW_STRING
2516	ABD
1678	A
20982	BADA

Re: Loop or Array?

novinosrin — Sat, 21 Sep 2019 22:19:46 GMT

Hi @BaileyY Very straight forward

data have;
input ID	Summer $	Price;
cards;
2516	A	269
1678	A	240
20982	B	125
2516	B	452
20982	A	315
2516	D	804
20982	D	804
20982	A	200
;

data _null_ ;
if _n_=1 then do;
   dcl hash H () ;
   h.definekey  ("id") ;
   h.definedata ("id","want") ;
   h.definedone () ;
end;
set have end=z;
if h.find() ne 0 then want=Summer;
else want=cats(want,summer);
h.replace();
if z;
h.output(dataset:'want');
run;

Re: Loop or Array?

novinosrin — Sat, 21 Sep 2019 22:26:18 GMT

proc sql;
create index id on have(id);
quit;

data want;
 do until(last.id);
  set have;
  by id;
  length want $50;
  want=cats(want,summer);
 end;
 keep id want;
run;

Re: Loop or Array?

BaileyY — Sat, 21 Sep 2019 22:37:25 GMT

omg!! Thank you so much. This worked perfectly!!