topic Re: create a range of date in SAS Procedures

create a range of date

sasphd — Thu, 18 Apr 2019 18:11:42 GMT

I want to create a table that create a window of date from in initial date by moving forwad and retreat by month

I have the following data

data HAVE;
input id :best32. caldt :mmddyy10. ;
format caldt date9.;
datalines;
1 1/1/2013
2 2/1/2014

;
run;

data want;
input id :best32. newcaldt :mmddyy10. ;
format newcaldt date9.;
datalines;
1 11/1/2012
1 12/1/2012
1 1/1/2013
1 2/1/2013
1 3/1/2013
2 11/1/2013
2 12/1/2013
2 2/1/2014
2 3/1/2014
2 4/1/2014

;
run;

Re: create a range of date

PaigeMiller — Thu, 18 Apr 2019 18:33:40 GMT

data want;
    set have;
	do month=-2 to 2 by 1;
	    newcaldate=intnx('month',caldt,month,'b');
		output;
	end;
	format newcaldate mmddyy10.;
	drop month caldt;
run;

By the way, I think you typed the dates in the want data set incorrectly, if I am understanding the problem correctly.

Re: create a range of date

ballardw — Thu, 18 Apr 2019 18:33:03 GMT

Your example data implies that you want the beginning of the month for two months prior and two months after the date. If that is the complete rule then this does that:

data want;
   set have;
   format newcaldt date9.;
   do i=-2 to 2;
      newcaldt= intnx('month',caldt,i,'B');
      output;
   end;
   drop i;
run;

I left in the original date variable so you could verify what is going on.