topic Re: How do I left align picture format labels in SAS Procedures

How do I left align picture format labels

rhale — Fri, 22 Mar 2019 10:34:04 GMT

I would like my format labels left aligned. How do I achieve this? In fact why aren't they left aligned already? My prefix is "Group " not " Group "...

proc format;
    picture sgb 1-4='9' (prefix='Group ')
                5-high='9 (mean)' (prefix='Group ')
    ;
run;

data test;
    do i = 1, 11;
        output;
    end;
    format i sgb.;
run;

I'm using SAS 9.4M5. Suggestions gratefully received!

Thanks in advance.

Re: How do I left align picture format labels

PeterClemmensen — Fri, 22 Mar 2019 10:55:26 GMT

I don't think this is possible directly with a picture format. Numeric values are always right aligned, picture format or not.

I think the best choice is to use the PUT Function with the -L alignment specification like this (The -L is default, so you don't actually need it).

proc format;
    picture sgb 1-4='9' (prefix='Group ')
                5-high='9 (mean)' (prefix='Group ')
    ;
run;

data test;
    do i = 1, 11;
        var=put(i, sgb. -l);
        output;
    end;
    
run;

proc print data=test;
run;

This gives you

Re: How do I left align picture format labels

rhale — Fri, 22 Mar 2019 11:32:28 GMT

Ah ok, pity, but that basically confirms my thinking - thanks! PUT doesn't really help me as I need a numeric variable with a format attached (for testing purposes).

Re: How do I left align picture format labels

Tom — Fri, 22 Mar 2019 12:52:59 GMT

Use PROC REPORT to display the values.

proc report data=test;
 define i / display left format=sgb.;
run;

Re: How do I left align picture format labels

andreas_lds — Fri, 22 Mar 2019 12:59:56 GMT

I don't this can be done in a dataset, but, of course in a report:

proc format;
    picture sgb 1-4='9' (prefix='Group ')
                5-high='9 (mean)' (prefix='Group ')
    ;
run;

data test;
    do i = 1, 11;
        output;
    end;    
run;

proc print data=test;
    var i / style(data)=[textalign=left];
    format i sgb.;
run;