topic Re: proc arima data= SASHELP.HEART; in SAS Procedures

proc arima data= SASHELP.HEART;

knjohns0 — Sun, 27 Jan 2019 18:52:38 GMT

Can anyone please help me with the understanding and the use of proc arima data= SASHELP.HEART;. What is it used/purpose for and its feature.

Thanks,

Kiera

Re: proc arima data= SASHELP.HEART;

Cynthia_sas — Sun, 27 Jan 2019 19:04:47 GMT

Hi:

It would be more useful if you could explain what it is you want/need to know.

If you don't understand the purpose of PROC ARIMA or how to use it, here's the documentation site: https://support.sas.com/documentation/onlinedoc/ets/151/arima.pdf and here's a clip from the Overview in that document:

If you need more information about SASHELP.HEART, look it up here: https://support.sas.com/documentation/tools/sashelpug.pdf .

Cynthia

Re: proc arima data= SASHELP.HEART;

knjohns0 — Sun, 27 Jan 2019 21:41:49 GMT

I am Analyzing Framingham Heart Data, the correlation between smoking and cholesterol data.

Re: proc arima data= SASHELP.HEART;

Reeza — Sun, 27 Jan 2019 22:46:43 GMT

Arima is for time series analysis, first decide on your method of analysis, ie linear regression, logistic regression and then we can help you with the coding part. Coding is relatively easy, figuring out what to code is hard.

Re: proc arima data= SASHELP.HEART;

knjohns0 — Mon, 28 Jan 2019 00:24:56 GMT

I am thinking Linear, since I am looking for a cause and effect. So, my study is based on the effects smoking has on cholesterol if any.

Re: proc arima data= SASHELP.HEART;

Reeza — Mon, 28 Jan 2019 01:48:11 GMT

@knjohns0 wrote:

I am thinking Linear, since I am looking for a cause and effect. So, my study is based on the effects smoking has on cholesterol if any.

This should get you started and finished. It's more than you need, but a good example of looking at the data and doing an exploratory data analysis. There are missing data - I haven't attempted to account for that in any manner, just exploratory. Good Luck.

ods graphics on;
title 'Exploratory Data Analysis';
title2 'Check Distributions';
proc freq data=sashelp.heart;
table chol_status smoking_status / missing;
table smoking cholesterol / missing;
run;

title2 'Ensure missing is consistent across variables';;

proc freq data =sashelp.heart;
table cholesterol*chol_status / missing;
table smoking*smoking_status / missing;
run;


title2 'Check distributions';
proc univariate data=sashelp.heart plots;
histogram smoking cholesterol;
var smoking cholesterol;
run;

title2 'Check distributions by status levels';
proc univariate data=sashelp.heart plots;
class chol_status;
var smoking ;
run;

title2 'Check distributions by status levels';
proc univariate data=sashelp.heart plots;
class smoking_status;
var cholesterol ;
run;


title2 'ANOVA comparisons and statistics';
proc anova data=sashelp.heart plots(maxpoints=10000);
class smoking_status; 
model cholesterol = smoking_status;
run;

title2 'Chi Square tests - status only';
proc freq data=sashelp.heart ;
table chol_status * smoking_status/ missing chisq;
run;

title2 'Regression modelling with continuous variables';
proc reg data=sashelp.heart plots(maxpoints=10000);
model cholesterol = smoking;
run;quit;

Re: proc arima data= SASHELP.HEART;

knjohns0 — Mon, 28 Jan 2019 02:57:38 GMT

Thanks, for your help.