topic Increasing font size in a histogram in SAS Procedures

Increasing font size in a histogram

Amanda_Lemon — Tue, 17 Jul 2018 14:00:12 GMT

Hello,

I am trying to increase the font size of both labels and tick values for both x-axis and y-axis. Is there an easy way to do that?

proc univariate data = data noprint;
class Group;
histogram Test / nrows = 3 normal;
run;

Thank you in advance.

Re: Increasing font size in a histogram

PaigeMiller — Tue, 17 Jul 2018 14:14:24 GMT

If the histogram has to be in PROC UNIVARIATE, then I think the only solution (which would be difficult) is to modify the template.

If you can do this in PROC SGPLOT, then the solution is simple.

Re: Increasing font size in a histogram

PeterClemmensen — Tue, 17 Jul 2018 14:16:10 GMT

These things are easier to control in PROC SGPLOT doing something like this

title "Some Histogram";
proc sgplot data=sashelp.iris;
  histogram SepalLength;
  xaxis labelattrs=(size=12 weight=bold) valueattrs=(size=12 weight=bold);
  yaxis labelattrs=(size=12 weight=bold) valueattrs=(size=12 weight=bold);
run;
title;

Re: Increasing font size in a histogram

Amanda_Lemon — Tue, 17 Jul 2018 14:40:50 GMT

I thought about sgplot but can it make 3 histograms placed nicely one under another? Like proc univariate does.

Re: Increasing font size in a histogram

PaigeMiller — Tue, 17 Jul 2018 14:47:48 GMT

Good point. To get histograms vertically above of one another, use PROC SGPANEL.

Re: Increasing font size in a histogram

PeterClemmensen — Tue, 17 Jul 2018 14:54:37 GMT

Use PROC SGPANEL and do something like this

proc sgpanel data=sashelp.iris;
   panelby species / rows=3;
   histogram SepalLength;
   rowaxis labelattrs=(size=12 weight=bold) valueattrs=(size=12 weight=bold);
   colaxis labelattrs=(size=12 weight=bold) valueattrs=(size=12 weight=bold);
run;

Re: Increasing font size in a histogram

Amanda_Lemon — Tue, 17 Jul 2018 15:22:35 GMT

Got it -- thank you!