topic Re: apply format to proc print without var in SAS Procedures

apply format to proc print without var

csetzkorn — Mon, 14 May 2018 09:58:12 GMT

This works fine:

proc format; 
 value Bla 
    low -< -1.0 = "red" 
    -1 -< 0 = "green"
	0 - high = "white"; 
run;

proc print data=Temp NOOBS; 
	var X Y Z
	/style(data) = [background=Bla.];	 
run;

I am in a situation where my vars are dynamic so I cannot use the /style option. Is there a way to apply the above format to all numeric values in the table to be printed?

Re: apply format to proc print without var

RW9 — Mon, 14 May 2018 10:32:21 GMT

Something like:

proc print data=temp noobs;
  var x y z;
  format _numeric_ bla.;
run;

Re: apply format to proc print without var

csetzkorn — Mon, 14 May 2018 10:36:49 GMT

Thanks. Firstly I cannot use var. Secondly (tried this) but it does not change the background color but prints the format values.

Re: apply format to proc print without var

RW9 — Mon, 14 May 2018 10:50:01 GMT

You can always use var, even if its a matter of doing:

proc sql;
  select name into :vlist separated by " " 
  from sashelp.vcolumn 
  where libname="WORK" and memname="TEMP";
quit;

proc print data=temp;
  var &vlist.;
run;

"Can't" is not in programming.

As for the issue, the key is to use the _numeric_ SAS command, which means all numeric variables:

proc print data=temp;
  var _numeric_ / style(data)=[background=bla.];
run;

Re: apply format to proc print without var

csetzkorn — Mon, 14 May 2018 12:58:38 GMT

wow this is exactly what I needed (-: