topic Macros in SAS Procedures

Macros

Meghana3 — Sat, 28 Apr 2018 19:16:45 GMT

Need help fixing this code

%macro random_number(seed,random_number);
   /**********************************************************************
   ****This macro uses seed to produce a random number between 0 and 1****
   ****The random number will be in a macro variable named in         ****
   ****the argument random_number.                                    ****
   **********************************************************************/

   data _null_;
   random_number = ranuni(&seed);
   call symput('&random_number', strip(random_number));
   stop;
   run;

   %put The random number is &random_number;

   %mend;

   %random_number(12345677,my_rand);
   %put The random number is &&&my_rand;

Re: Macros

kiranv_ — Sat, 28 Apr 2018 19:27:18 GMT

instead of saying fix this code, if you can write/mention the issue/problem then someone can easily fix it.

Thanks

Kiran

Re: Macros

Reeza — Sat, 28 Apr 2018 19:32:46 GMT

Macro variables only resolve in double quotes, not single quotes, and you don't need multiple & in this usage. You also can't have a macro variable named as a numeric so that would be problematic, CALL

The first argument to CALL SYMPUT should be the macro variable name, which cannot be the same as the value in this case.

And you should use CALL SYMPUTX instead as well.

That's my guess at your issue, you didn't really say what's wrong and I didn't run your code either.

@Meghana3 wrote:

Need help fixing this code

%macro random_number(seed,random_number);
   /**********************************************************************
   ****This macro uses seed to produce a random number between 0 and 1****
   ****The random number will be in a macro variable named in         ****
   ****the argument random_number.                                    ****
   **********************************************************************/

   data _null_;
   random_number = ranuni(&seed);
   call symput('&random_number', strip(random_number));
   stop;
   run;

   %put The random number is &random_number;

   %mend;

   %random_number(12345677,my_rand);
   %put The random number is &&&my_rand;

Re: Macros

art297 — Sat, 28 Apr 2018 19:47:15 GMT

I think that the following does what you want:

%macro random_number(seed,random_number);
     /**********************************************************************
     ****This macro uses seed to produce a random number between 0 and 1****
     ****The random number will be in a macro variable named in         ****
     ****the argument random_number.                                    ****
     **********************************************************************/

     data _null_;
     random_number = ranuni(&seed);
     call symputx("&random_number.", random_number, 'G');
     stop;
     run;

     %mend;

%random_number(12345677,my_rand);
%put The random number is &my_rand;

Art, CEO, AnalystFinder.com

Re: Macros

Tom — Sat, 28 Apr 2018 20:05:07 GMT

You could use the %SYSFUNC() macro function and create a "function style" macro instead.

%macro random_number2(seed);
%local value;
%let value=%sysfunc(ranuni(&seed),best32.);
&value.
%mend;

%let my_rand=%random_number2(12345677);
%put The random number is &my_rand;

Re: Macros

art297 — Sat, 28 Apr 2018 21:24:45 GMT

Regardless of which style macro you choose, do realize that using the ranuni function via a macro will ALWAYS return the first number in that seed .. i.e., NOT a random number.

e.g., run the following code and compare the output files (i.e., dontwant and want):

%macro random_number2(seed);
  %local value;
  %let value=%sysfunc(ranuni(&seed),best32.);
  &value.
%mend;

data dontwant;
  do i=1 to 100;
    x=%random_number2(0);
    output;
  end;
run;

data want;
  do i=1 to 100;
    x=ranuni(0);
    output;
  end;
run;

Art, CEO, AnalystFinder.com