topic Re: Run macro only if obs > 0 in SAS Procedures

Run macro only if obs > 0

Ltwo — Fri, 18 Aug 2017 03:38:39 GMT

Hi,

I've got a macro set up but I want SAS to only run it when the number of observations in the input dataset >0

So for example, for the code below, I only want it to run for datasets that aren't empty. Assume that dataset source2 is empty in this instance.

%macro abc(input);

data want;
set &input.;
run;

%mend abc;

%abc(source1);
%abc(source2);
%abc(source3);

Re: Run macro only if obs > 0

SuzanneDorinski — Fri, 18 Aug 2017 04:36:28 GMT

options mprint;

data source1;
  set sashelp.class;
run;

data source2;
  input name;
  datalines;
   ;
run;

data source3;
  set sashelp.cars;
run;


%macro abc(input);

    proc sql noprint;
      select count(*) 
        into :obs_count
          from &input;
    quit;
    
    %if &obs_count gt 0 %then
      %do;
      
	    data want;
		  set &input.;
	    run;
	 %end;

%mend abc;

%abc(source1);
%abc(source2);
%abc(source3);

Re: Run macro only if obs > 0

Ltwo — Fri, 18 Aug 2017 04:59:26 GMT

Thanks heaps

Re: Run macro only if obs > 0

RW9 — Fri, 18 Aug 2017 12:57:44 GMT

data _null_;
  set sashelp.vtable (where=(libname="WORK" and substr(memname,1,6)="SOURCE" and nobs > 0));
  call execute(cats('%abc (',catx('.',libname,memname),');'));
run;

Simplest form, you can change WORK (must be upcase) to yout lib and use the where to restrict tables/libraries - for instance if you dropped the lib, it would check any dataset source: from any lib.