topic How to rank three orders within the same ID and count the number of observations for each order in SAS Procedures

How to rank three orders within the same ID and count the number of observations for each order

cpulala — Sun, 13 Aug 2017 03:47:59 GMT

Hi,

I have a dataset looks like below:

ID Visit CurrentTotal

1 0 0

1 0 1

1 1 0

1 0 3

1 1 2

1 1 1

1 1 0

For the same ID, there are three parts of data - the observations in black, red and blue. For each part, I need to count the total number of visits. Right now, the CurrentTotal variable is displayed in the dataset, which is not correct for the counts of each part (black, red and blue). What I would like to ask is that "How to add a variable "TargetTotal" as shown below to have the correct number of visit count for each part? How can the SAS codes be able to rank three orders within the same ID?" The order should start with 0, and end till the next 0, so there are three parts (the black, red and blue t) for the same ID.

ID Visit CurrentTotal TargetTotal

1 0 0 0

1 0 1 0

1 1 0 1

1 0 3 0

1 1 2 1

1 1 1 2

1 1 0 3

Thank you very much. Looking forward to the solutions.

Re: How to rank three orders within the same ID and count the number of observations for each order

PGStats — Sun, 13 Aug 2017 04:02:17 GMT

Assuming each part of your data starts at Visit=0 :

data have;
input ID   Visit;
datalines;
1      0   
1      0   
1      1   
1      0   
1      1   
1      1   
1      1   
;

data want;
do until(last.id);
    set have; by id;
    if visit = 0 then rank = 0;
    else rank = rank + 1;
    output;
    end;
run;

proc print noobs; run;

Re: How to rank three orders within the same ID and count the number of observations for each order

Kurt_Bremser — Sun, 13 Aug 2017 09:56:25 GMT

data want;
set have;
by id;
if visit = 0 then targettotal = 0;
else if first.id then targettotal = 1;
else targettotal + 1;
run;

Re: How to rank three orders within the same ID and count the number of observations for each order

Astounding — Sun, 13 Aug 2017 15:00:11 GMT

The simplest version would rely on VISIT only, to create TargetTotal:

data want;

set have;

if visit=0 then TargetTotal=0;

else TargetTotal + 1;

run;

Note that you don't have to worry about ID, when the first observation for each ID has VISIT=0. The program checks for VISIT=0, which automatically includes the first observation for each ID.

Re: How to rank three orders within the same ID and count the number of observations for each order

Ksharp — Sun, 13 Aug 2017 11:14:40 GMT


data have;
input ID   Visit;
datalines;
1      0   
1      0   
1      1   
1      0   
1      1   
1      1   
1      1   
;
data temp;
 set have;
 by id;
 if first.id or visit=0 then group+1;
run;
data want;
 set temp;
 by group;
 if first.group then total=-1;
 total+1;
run;

Re: How to rank three orders within the same ID and count the number of observations for each order

cpulala — Sun, 13 Aug 2017 14:11:19 GMT

Thanks! It works.

Re: How to rank three orders within the same ID and count the number of observations for each order

cpulala — Sun, 13 Aug 2017 14:12:18 GMT

Thanks! It works. But when the dataset has multiple IDs, a 'by ID;' statement need to be used.

Re: How to rank three orders within the same ID and count the number of observations for each order

cpulala — Sun, 13 Aug 2017 14:15:46 GMT

Thanks! All responses work. It is hard to decide which one is the best solution; I choose the answer with the earliest response.