topic Adding leading zeroes to character variable in SAS Procedures

Adding leading zeroes to character variable

GKati — Wed, 19 Jul 2017 10:32:42 GMT

Dear All,

I have a large dataset with diagnosis codes that are up to four digits. I need to make them more uniform by adding zeros preceding the first digit (letter) to make them 4 digits but in a character format.

I've tried this but I end up with all zeros.

data diagnosis;

input diagnosis;

datalines;

094

;

run;

data diagnosis;

set diagnosis;

diagnose=translate(right(diagnosis),'0',' ');

;

run;

My desired output would be this:

0094

0016

00E4

Re: Adding leading zeroes to character variable

Kurt_Bremser — Wed, 19 Jul 2017 10:40:29 GMT

First of all, your first data step won't really work, as you try to create a numeric variable, so add a dollar sign:

data diagnosis;
input diagnosis $;
datalines;
094
16
E4
;
run;

Then try this:

data diagnosis;
set diagnosis;
length newdiag $4;
newdiag = '0000';
substr(newdiag,5-length(diagnosis)) = diagnosis;
drop diagnosis;
rename newdiag=diagnosis;
run;

Re: Adding leading zeroes to character variable

RW9 — Wed, 19 Jul 2017 10:58:56 GMT

data want;
  var="E4";
  want=cats(repeat('0',3-lengthn(var)),var);
run;

Re: Adding leading zeroes to character variable

GKati — Wed, 19 Jul 2017 10:59:13 GMT

Perfect. This works well.

Re: Adding leading zeroes to character variable

Ksharp — Wed, 19 Jul 2017 13:10:06 GMT

data diagnosis;
input diagnosis $;
datalines;
094
16
E4
;
run;
data diagnosis;
set diagnosis;
length newdiag $4;
newdiag = diagnosis;
newdiag= translate(right(newdiag),'0',' ');
run;