topic Re: Proc Report Format Value via Compute in SAS Procedures

Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 15:00:00 GMT

Is there a way to use a compute block in proc report to display a numeric column as an integer in one line and percent on another?

Re: Proc Report Format Value via Compute

ballardw — Thu, 29 Jun 2017 15:09:44 GMT

@DavidPhillips2 wrote:

Is there a way to use a compute block in proc report to display a numeric column as an integer in one line and percent on another?

Is this supposed to be conditional on another value? Row number? How do you know which display you want on a given line? or do you mean to display both for every result but on separate lines, possibly stacked in a cell?

Re: Proc Report Format Value via Compute

Reeza — Thu, 29 Jun 2017 15:16:31 GMT

You can alias a column and list it twice.

http://support.sas.com/kb/41/576.html

Modifying it slightly:

data example;
   input a $  b $ mydate mmddyy8.; ;
   datalines;
wilma stone   01122001
wilma stone   02122001
wilma stone   01012001
fred  stone   03052008
fred  stone   03152008
fred  stone   03152009
;
run;

ods html;

title 'MIN and MAX date per patient';

proc report nowd data=example;
   column a b mydate=min_mydate mydate=max_mydate;
   define a / group;
   define b / group;
   define min_mydate / min format=mmddyy10. 'min date';
   define max_mydate / max format=date9. 'max date';
run;

ods html close;

Re: Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 15:21:01 GMT

How can I use this format conditionally? If a = 'wilma' then format 1?

Re: Proc Report Format Value via Compute

Reeza — Thu, 29 Jun 2017 15:32:45 GMT

 compute n;
  if name='Wilma' then call define('row','format','dollar10.');
   else call define('row', 'format', 'percent10.1');
 endcomp;

Re: Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 16:36:23 GMT

data example;
input a $ b $ mydate mmddyy8.;
datalines;
wilma stone 01122001
wilma stone 02122001
wilma stone 01012001
fred stone 03052008
fred stone 03152008
fred stone 03152009
;
run;

title 'MIN and MAX date per patient';

proc report nowd data=example;
column a b mydate=min_mydate mydate=max_mydate;
define a / group;
define b / group;
/*define min_mydate / min format=mmddyy10. 'min date';*/
define max_mydate / max format=date9. 'max date';
compute min_mydate;
if a='Wilma' then call define('min_mydate','format','dollar10.');
else call define('min_mydate', 'format', 'percent10.1');
endcomp;

run;

Results in

a b mydate max date

fred	stone	6595700%	15MAR2020
wilma	stone	6579800%	12FEB2020

aiming for

a b mydate max date

fred	stone	6595700%	15MAR2020
wilma	stone	$6579800	12FEB2020

Re: Proc Report Format Value via Compute

BrunoMueller — Thu, 29 Jun 2017 16:51:37 GMT

you test for Wilma whereas your data is wilma

Re: Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 16:58:06 GMT

Thanks

data example;
input a $ b $ mydate mmddyy8.;
datalines;
wilma stone 01122001
wilma stone 02122001
wilma stone 01012001
fred stone 03052008
fred stone 03152008
fred stone 03152009
;
run;

title 'MIN and MAX date per patient';

proc report nowd data=example;
column a b mydate=mydate2;
define a / group;
define b / group;
/*define min_mydate / min format=mmddyy10. 'min date';*/
/*define max_mydate / max format=date9. 'max date';*/
compute mydate2;
if a='wilma' then call define('mydate2','format','dollar10.');
else call define('mydate2', 'format', 'percent10.1');
endcomp;

run;

Re: Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 18:10:09 GMT

I am trying to display the data across so I added a comma in

column a b mydate=mydate2;

Is there something I’m missing to display the data across?

The below works but

data example;
input a $ b $ mydate mmddyy8.;
datalines;
wilma stone 01122001
wilma stone 02122001
wilma stone 01012001
fred stone 03052008
fred stone 03152008
fred stone 03152009
;
run;

title 'MIN and MAX date per patient';

proc report nowd data=example;
column a b mydate=mydate2;
compute mydate2;
if a='wilma' then call define('mydate2', 'format','dollar10.');
endcomp;
define a / group;
define b / across;

run;

This block produces ERROR: Invalid column specification in CALL DEFINE.

data example;
input a $ b $ mydate mmddyy8.;
datalines;
wilma stone 01122001
wilma stone 02122001
wilma stone 01012001
fred stone 03052008
fred stone 03152008
fred stone 03152009
;
run;

title 'MIN and MAX date per patient';

proc report nowd data=example;
column a b, mydate=mydate2;
compute mydate2;
if a='wilma' then call define('mydate2', 'format','dollar10.');
endcomp;
define a / group;
define b / across;

run;

Re: Proc Report Format Value via Compute

DavidPhillips2 — Thu, 29 Jun 2017 18:24:32 GMT

This worked.

title 'MIN and MAX date per patient';

proc report nowd data=example;
column a b, mydate;
compute mydate;
if a='wilma' then call define(_col_, 'format','dollar10.');
endcomp;
define a / group;
define b / across;

run;