topic Proc format truncation of values in SAS Procedures

Proc format truncation of values

devarayalu — Wed, 19 Apr 2017 11:05:19 GMT

Hi All,

The formatted values were gettng truncated to a length of 20, when the data have the values which were not covered in below expected values.

Ex: Raw data: "Once every 6 months in 2 cycles 15 days apart", which is not present in the proc format.

Formatted value: "Once every 6 months" instead of full length value.

Could you please help on this.

PROC FORMAT LIBRARY=work;
Value $CMFREQ

"1" = "BID"
"2" = "TID"
"3" = "QID"
"4" = "QD"
"5" = "QM"
"6" = "PRN"
"7" = "Twice in the morning"
"8" = "Twice in the evening"
"9" = "Before meals"
"Q 6 months"= "Q6M"
;
run;

data cm;
length cmfreq $100.;
set raw.cm;
where cmfreqot ne '';
cmfreq = put(cmfreqot, $CMFREQ.);

keep cmfreqot cmfreq;
run;

Thank you

Re: Proc format truncation of values

RW9 — Wed, 19 Apr 2017 11:46:33 GMT

Yes, tricky one. Had to think about it for a while. Simplest way is to put other= and specify the format:

proc format library=work;
 value $cmfreq
    "1" = "BID"
    "2" = "TID"
    "3" = "QID"
    other=[$100.]
    ;
run;

data cm;
  length cmfreq cmfreqtot $100.;
  infile datalines dlm="¬" missover;
  input cmfreqtot $;
  cmfreq=put(cmfreqtot, $CMFREQ.);
datalines;
3
A really long string which should push the twenty character bounds
;
run;

Re: Proc format truncation of values

Tom — Wed, 19 Apr 2017 11:54:57 GMT

You can define a default width when you define the format.

PROC FORMAT LIBRARY=work;
 value $CMFREQ (default=100) 
 "1" = "BID"
 "2" = "TID"
 "3" = "QID"
 "4" = "QD"
 "5" = "QM"
 "6" = "PRN"
 "7" = "Twice in the morning"
 "8" = "Twice in the evening"
 "9" = "Before meals"
 "Q 6 months"= "Q6M"
;
run;

Or you can specify the width when you use the format.

cmfreq = put(cmfreqot, $CMFREQ100.);

Re: Proc format truncation of values

devarayalu — Wed, 19 Apr 2017 11:55:23 GMT

Many Thanks for your swift response. Issue solved now.

Much appreicated.

Re: Proc format truncation of values

Jagadishkatam — Wed, 19 Apr 2017 12:03:13 GMT

PLease try the default=100 in proc format

like below

PROC FORMAT LIBRARY=work;
Value $CMFREQ (default=100)
"1" = "BID"
"2" = "TID"
"3" = "QID"
"4" = "QD"
"5" = "QM"
"6" = "PRN"
"7" = "Twice in the morning"
"8" = "Twice in the evening"
"9" = "Before meals"
"Q 6 months"= "Q6M"
;
run;

Re: Proc format truncation of values

Ksharp — Wed, 19 Apr 2017 12:05:44 GMT

cmfreq = put(cmfreqot, $CMFREQ100.);

Re: Proc format truncation of values

BrunoMueller — Wed, 19 Apr 2017 12:12:17 GMT

Another way would be, to specify the default length for the format. See sample below.

proc format library=work;
 value $cmfreq (default=100)
    "1" = "BID"
    "2" = "TID"
    "3" = "QID"
    ;
run;

data cm;
  infile datalines dlm="¬" truncover;
  input cmfreqtot $100.;
  cmfreq=put(cmfreqtot, $CMFREQ.);
datalines;
3
2
1
A really long string which should push the twenty character bounds
abc
;

Bruno

Re: Proc format truncation of values

devarayalu — Wed, 19 Apr 2017 14:05:01 GMT

Thank you Jagadish