topic Re: Incorrect output as result of a user-defined format in SAS Procedures

Incorrect output as result of a user-defined format

bsas94 — Fri, 11 Nov 2016 16:02:20 GMT

Hi experts,

I would like to know why I am not getting the results I expected using the following proc fcmp and proc format:

/**create function**/
proc fcmp outlib = work.functions.myfuncs;
function addZeros(x $) $;

sizeZ = lengthm(x)-length(x)-1;
res = catt(repeat('0', sizeZ,x);
return (res);
endsub;
run;

/**create new format***/
proc format;
value $addFormatTest other=[addZeros()];
run;

data sample;
 
  input x $15. ;
 
 
  y=x;
  len = length(x);
  lenm = lengthm(x);
  nrZeros = lengthm(x) - length(x);
 
  format y $addFormatTest.;
  z=put(x, $addFormatTest.);
 
datalines;
anothertest
test
tes
;
 
run;

This format was supposed to add leading zeros but it is writing more zeros than it should.

Any Ideas?

Thanks a lot

Re: Incorrect output as result of a user-defined format

LinusH — Fri, 11 Nov 2016 16:38:58 GMT

Yeah, use z. instead.

Re: Incorrect output as result of a user-defined format

bsas94 — Fri, 11 Nov 2016 16:49:28 GMT

Definition found in https://support.sas.com/documentation/cdl/en/leforinforref/63324/HTML/default/viewer.htm#p09lpr3kmbh8fen1qepuv6zc1ldd.htm

Zw.d Format

Writes standard numeric data with leading 0s.

Category:	Numeric

Alignment:	right

I want to add zeros to a character variable and I will use it as a format in SAS Information Map and in SAS Marketing Automation export definitions.

Tks,

Re: Incorrect output as result of a user-defined format

PGStats — Fri, 11 Nov 2016 21:04:55 GMT

Got it to work with:

/**create function**/
proc fcmp outlib = work.functions.myfuncs;
function addZeros(x $) $32;
sizeZ = lengthm(x)-length(x)-1;
res = catt(repeat('0', sizeZ), x);
return (res);
endsub;
run;

options cmplib=work.functions;

/**create new format***/
proc format;
value $addFormatTest (default=32) other=[addZeros()];
run;

data sample;
 
  input x $15. ;
 
 
  y=x;
  len = length(x);
  lenm = lengthm(x);
  nrZeros = lengthm(x) - length(x);
 
  format y $addFormatTest.;
  z=put(x, $addFormatTest.);
 
datalines;
anothertest
test
tes
;

Added missing parenthesis on REPEAT function call, cmplib option, and (default=) specification in value statement of proc format.