topic Re: max value in SAS Procedures

max value

ESSALAHBENNANI — Sat, 27 Aug 2016 15:11:00 GMT

Each ID has several instances, and each instance has a different value. I would like the final output to be the maximum value per ID and per year. So the initial dataset is:

ID   year  Value
 1   2012   100
 1   2013   7
 1   2013   65
 2   2015   12
 2   2015   97
 3   2011   82
 3   2012   54
 3   2012   95

And the output will be :

 ID   year  Value
 1    2012   100
 1    2013   65
 2    2015   97
 3    2011   82
 3    2012   95
I tried running proc means :
proc means data=H10 noprint;
 class ID year ; 
 var value;
 output out=want max(value)=;
run;

but it dosen't work.

thx u very much.

Re: max value

Jagadishkatam — Sat, 27 Aug 2016 16:37:48 GMT

try proc sql

proc sql;
create table max as select id, year, max(value) as value from have group by id, year;
quit;

Re: max value

Jagadishkatam — Sat, 27 Aug 2016 16:40:19 GMT

with proc means try

proc means data=have noprint;
by id year;
var value;
output out=max max=value;
run;

Re: max value

ESSALAHBENNANI — Sat, 27 Aug 2016 17:15:51 GMT

or
proc means data=sortedOutput noprint;
class id ; by year;
var value;
output out=want3 max(value)=;
run;

thx u

Re: max value

Reeza — Sat, 27 Aug 2016 18:14:37 GMT

Your original code was correct, you don't specify how it was wrong but I suspect it had too many points because it calculates ALL interactions between year and ID, so the max for each ID, the max for each year and then the max for each Year/ID which is the one you actually want. You can limit your results with the NWAY option.

I like to specify the variable name, but its not required.

proc means data=H10 noprint NWAY;
 class ID year ; 
 var value;
 output out=want max(value)=max_value;
run;

Re: max value

ESSALAHBENNANI — Sat, 27 Aug 2016 19:47:12 GMT

exactly thx u verry much