topic Re: Text dates to a Sas date in SAS Procedures

Text dates to a Sas date

LK357 — Wed, 13 Jul 2016 18:06:38 GMT

how can I convert this text to a date I can use in SAS.?

April 1, 2016

currently stored as CHAR $18

thanks

Re: Text dates to a Sas date

Astounding — Wed, 13 Jul 2016 18:46:00 GMT

Typically:

sas_date = input(string_date, worddate18.);

Then apply a format to SAS_DATE such as:

format sas_date yymmdd10.;

format sas_date date9.;

Re: Text dates to a Sas date

LK357 — Wed, 13 Jul 2016 18:52:00 GMT

Thanks for the response but im getting the following error...

sas_date = input(date, worddate18.);
-----------
48
ERROR 48-59: The informat WORDDATE was not found or could not be loaded

Re: Text dates to a Sas date

Reeza — Wed, 13 Jul 2016 19:00:06 GMT

Usually there's an informat for the date, but this doesn't have an informat that I could find.

You can create it into a date format that SAS will recognize, I used Date9. format, since it's the most common in SAS.

I use the SUBSTR, SCANx2 function to extract the month, day and year, respectively, and the CATT to concatenate them together.

data have;
informat date_char $20.;
input date_char $20.;
cards;
April 1, 2016
December 24, 2016
April 30, 2015
May 18, 2014
November 1, 2012
February 28, 2016
;
run;

data want;
set have;
date_format9 = catt(put(input(scan(date_char, 2), 2.), z2.),
			 substr(date_char, 1, 3),
			  scan(date_char, 3)
			  );
			  
date_num = input(date_format9, date9.);
format date_num date9.;
run;

Re: Text dates to a Sas date

ballardw — Wed, 13 Jul 2016 19:06:56 GMT

data want;

set have;

Sasdate = input(textdate, anydtdte32.);

format Sasdate mmddyy10.;

run;

Re: Text dates to a Sas date

Astounding — Wed, 13 Jul 2016 19:07:57 GMT

You guys are right! There's a WORDDATE18 format, but not a WORDDATE18 informat.

Reeza's idea looks good. I might simplify one part:

date_format9 = cats( scan(date_char, 2, ' ,'), substr(date_char, 1, 3), scan(date_char, 3) );

Note that both blanks and commas are being used as delimiters in the first SCAN function.

Re: Text dates to a Sas date

Reeza — Wed, 13 Jul 2016 19:09:24 GMT

@ballardw Interesting. I tried with ANYDTDTE but didn't specify a width, and that didn't work. I forgot there's a default width 🙂

Re: Text dates to a Sas date

ballardw — Wed, 13 Jul 2016 21:25:41 GMT

@Reeza wrote:

@ballardw Interesting. I tried with ANYDTDTE but didn't specify a width, and that didn't work. I forgot there's a default width 🙂

I had done the samething recently with width up to 20. Apparently some of the things anydt reads only work with maximum lengths.

Re: Text dates to a Sas date

LK357 — Thu, 14 Jul 2016 09:42:34 GMT

Thank you for this it works fine and is a lot simpler!.

Re: Text dates to a Sas date

LK357 — Thu, 14 Jul 2016 10:54:21 GMT

Hi there,

Is there a similar solution to extract the time from this text var format $25.

12:30PM:Friday:Weekday