topic How assign result of procedure to one variable? in SAS Procedures

How assign result of procedure to one variable?

bigban777 — Thu, 21 Apr 2016 15:38:52 GMT

How i can assign result of procedure to variable?

For example i need assign standard deviation value to variable SD from

PROC MEANS STD DATA = smoke3;

run;

So i can use it to find margin of error:

me=SD/sqrt(n);

Thank you

How assign result of procedure to one variable?

bigban777 — Thu, 21 Apr 2016 15:57:27 GMT

How i can assign result of procedure to variable?

For example i need assign standard deviation value to variable SD from

PROC MEANS STD DATA = smoke3;

run;

So i can use it to find margin of error:

me=SD/sqrt(n);

Thank you

Re: How assign result of procedure to one variable?

ballardw — Thu, 21 Apr 2016 16:07:53 GMT

Generate a data set with the summary values you want and then in a data step do additional calculations:

I tend to prefer Proc summary which does basically the same as proc means but default output sets are structured differently.

Here is an example using the SASHELP.Class data set. Proc summary will require the names of the analyis variables, a variable list, or use of the keyword _numeric_ on the VAR statement. The autoname creates output variables named as your input variables with a suffix of the statistic requested.

Proc summary data=sashelp.class;
   var Age Height Weight;
   output out=work.sum std= n= /autoname;
run;
data want;
   set work.sum;
   AgeMe = age_StdDev/sqrt(Age_N);
   HeightMe = Height_StdDev/sqrt(Height_N);
   WeightMe = Weight_StdDev/sqrt(Weight_N);
run;

Re: How assign result of procedure to one variable?

Kurt_Bremser — Thu, 21 Apr 2016 16:27:07 GMT

Create an output dataset with the output statement in proc means. Then run a data _null_ step from that dataset and use call symput to create a macro variable.

Re: How assign result of procedure to one variable?

Reeza — Thu, 21 Apr 2016 16:41:00 GMT

One other solution, because sometimes you want the statistics back in the original data set is to SET it back in.

The variables from proc summary will be added to the want data set for inclusion.

PS if you're looking to standardize or scale variables also take a look at PROC STANDARD and STDIZE.

Proc summary data=sashelp.class;
   var Age Height Weight;
   output out=work.sum std= n= /autoname;
run;

data want;
if _n_ = 1 then set sum;
set sashelp.class;

run;

Re: How assign result of procedure to one variable?

Ksharp — Fri, 22 Apr 2016 01:47:57 GMT

That is called standard error . You don't need another SAS statement to calculated it. PROC MEANS would do it for you .

proc means data=sashelp.class std stderr;
   var Age Height Weight;
run;