topic Re: how to create new group/type variable in SAS Procedures

how to create new group/type variable

vonsel — Wed, 02 Mar 2016 10:23:19 GMT

I want to create the new group/type variable. I have variables ID and PRICE and want to create the variable COLL.

So for each ID i want the type variable COLL, to check whether the price is still the same. So my final table will be:

How can I do it in proc data or proc sql?

Re: how to create new group/type variable

RW9 — Wed, 02 Mar 2016 10:23:55 GMT

Here you go, do not for future posts, put test data in the form of a datastep, as given below:

data have;
  input id price;
datalines;
1 1000
1 1000
1 2000
2 1000
2 1000
3 5000
3 5000
3 7000
;
run;

data want;
  set have;
  by id price;
  retain coll;
  if first.id then coll=1;
  else if first.price then coll=coll+1;
run;

Re: how to create new group/type variable

FreelanceReinh — Wed, 02 Mar 2016 10:53:13 GMT

Hi @vonsel,

If prices can change in both directions (as is the case for ID 3 in your sample data), you need to add the NOTSORTED option to the BY statement: by id price notsorted;

Here's a minor variant of RW9's solution:

data want;
set have;
by id price notsorted;
coll+first.price;
if first.id then coll=1;
run;

Obviously, the numbering in COLL depends on the sort order of the observations. So, I hope you have an additional variable in your real data which determines the sort order within each ID (or you have good reason to believe that the existing sort order is correct).

Re: how to create new group/type variable

vonsel — Wed, 02 Mar 2016 11:36:01 GMT

Thanks a lot, both solutions work.