topic Re: How to delete all variables with the names as ???f in SAS Procedures

How to delete all variables with the names as ???f

JamesKauley — Fri, 06 Jan 2012 01:21:51 GMT

Hello,

I have a dataset which has many variables. I don't need those variables which has 'f' in the last position of the name. For example, the names of those variables are like wagef, levelf, posf.

Thanks for help.

Re: How to delete all variables with the names as ???f

Linlin — Fri, 06 Jan 2012 01:40:48 GMT

data have;

input aaf bbbf ccc;

cards;

1 2 4

2 3 8

;

proc sql noprint;

select name into : names separated by ' '

from dictionary.columns

where libname='WORK' and memname='HAVE' and lowcase(substr(name,length(name),1))='f';

quit;

data want;

set have (drop=&names);

run;

proc print;run;

Obs ccc

1 4

2 8

Linlin

How to delete all variables with the names as ???f

Patrick — Fri, 06 Jan 2012 01:41:42 GMT

data have;
   wagef=1;
   wage=1;
   wagefn=1;
   xageF=1;
run;

%let dellist=;
proc sql;
   select name into :dellist separated by ','
   from dictionary.columns
   where libname='WORK' and memname='HAVE' and upcase(name) like '%F'
   ;
   %macro _del;
      %if %bquote(&dellist) ne %bquote() %then
      %do;
         alter table work.have
            drop &dellist
         ;
      %end;
   %mend;
   %_del
quit;

proc contents data=work.have;
quit;

Re: How to delete all variables with the names as ???f

Ksharp — Fri, 06 Jan 2012 06:00:28 GMT

Combination of Patrick and LinLin.

proc sql noprint;

select name into : names separated by ' '

from dictionary.columns

where libname='WORK' and memname='HAVE' and upcase(name) like '%F' ;

quit;

Ksharp