topic Re: tranposing? in SAS Procedures

tranposing?

aarony — Wed, 13 Jan 2016 02:08:15 GMT

hi i have data with 4 variables:

year, month,company, return

i want to compound the monthly return to annual. so that for each year:

(1+january return)*(1+feb return).....*(1+dec return)

does anyone know a smart way to do this?

many thanks!

Re: tranposing?

Ksharp — Wed, 13 Jan 2016 02:43:59 GMT

data and output ?

Re: tranposing?

aarony — Wed, 13 Jan 2016 02:54:20 GMT

Could u be a bit more specific? Thx so mcuh!!

Re: tranposing?

PGStats — Wed, 13 Jan 2016 03:00:12 GMT

Try

proc sql;
create table compound as
select 
	company, 
	year, 
	exp(sum(log(1+return))) - 1 as compoundedReturn
from myData
group by company, year;
quit;

Re: tranposing?

Reeza — Wed, 13 Jan 2016 03:21:05 GMT

@aarony wrote:
Could u be a bit more specific? Thx so mcuh!!

@PGStats is stating that your question is unclear and asking if you can provide sample input data with matching output so your problem can be easily understood. In other words, can you be more specific about your question 🙂

Re: tranposing?

JohndeKroon — Wed, 13 Jan 2016 07:11:16 GMT

Hi,

I just made a small assumption on how your data would look like given your request! First I used a transpose (1 line per company per year, with an entry for each month). Then I used a data step icw array-function to determine the yearly return:

data input (drop =  i);
	format company $13.;
	do i = 1 to 12;
		year = 2016;
		month = i;
		company = 'A';
		return = i/100;
		output;
		company = 'B';
		return = (i+1)/100;
		output;
	end;
run;

proc sort data=input out=sortedInput;
	by year company month;
run;

proc transpose date=sortedInput out=tInput prefix=M;
	by company year;
	id month;
run;

data output (drop=i);
	set tInput;
	array allMonths(12) M1-M12;
	yearReturn = 1;
	do i = 1 to dim(allMonths);
		yearReturn = yearReturn*(1+allMonths[i]);
	end;
	yearReturn = yearReturn -1;
run;

Hope this helps.

John