topic Re: how to merge variables in SAS Procedures

how to merge variables

sasbasls — Mon, 04 Jan 2016 22:56:06 GMT

I have data something like this -

id1 abc

id1 def

id2 pqr

id2 rst

------ etc

I want to have like this in output dataset -

id1 abc/def

id2 pqr/rst

thanks in advance,

Re: how to merge variables

FreelanceReinh — Mon, 04 Jan 2016 23:09:44 GMT

Try this:

data have;
input id $ text $;
cards;
id1   abc
id1   def
id2   pqr
id2   rst
;

data want;
length alltext $30; /* Please adapt the length 30 to your needs! */
do until(last.id);
  set have;
  by id;
  alltext=catx('/', alltext, text);
end;
drop text;
run;

proc print data=want;
var id alltext;
run;

If you want to have ID as the first variable in the dataset (and not only in the output), you can move the LENGTH statement after the SET statement, immediately before the assignment alltext=....

Re: how to merge variables

Reeza — Mon, 04 Jan 2016 23:10:42 GMT

And if you don't understand the do loop before the SET statement here's another, old fashioned method. @FreelanceReinh solution is probably more efficient.

data want;
set have;
by id;

length var $100.;
retain var;

if first.id then call missing(var);
var=catx('/', var, text);

if last.id then output;
run;

proc print;run;