Proc report note clarification

Maddy4u — Fri, 09 Oct 2015 12:36:57 GMT

Hi All,

I am currently starter in using the SAS Proc report procedure, Could you please look in the below note and help me out on what exactly it issue is:

My data&colon;

data sample:

input flightid $ Expenses;

datalines;

IA03400 89155

;

run;

My proc report code is as below:

proc report data=sample.expenses nowd;
column flightid expenses abh;
define abh / computed ;
   compute abh;
    abh=expenses*100;
   endcomp;
run;

With the above code I am having a note in the log as "Variable expenses is uninitialized."

Is this something that we cannot refer the variable which is already existing in the dataset for compute.

Thank you

Re: Proc report note clarification

BrunoMueller — Fri, 09 Oct 2015 13:12:43 GMT

Have a look at the doc for proc report, specifically Four Ways to Reference Report Items in a Compute Block. Since EXPENSES is a numeric variable, its default usage is ANALYSIS with statistic SUM, so you need write it like

data sample;
  input flightid $ Expenses;
  datalines;
IA03400 89155
;
run;

proc report data=sample nowd;
  column flightid expenses abh;
  define abh / computed;

  compute abh;
    abh = expenses.sum * 100;
  endcomp;
run;

Bruno

topic Re: Proc report note clarification in SAS Procedures

Proc report note clarification

Re: Proc report note clarification