topic How to format date values in Proc SQL in SAS Procedures

How to format date values in Proc SQL

mohancs — Thu, 01 Oct 2015 10:01:56 GMT

Given Format - YYYYMM Required Format - YYMMDD (default dd to 01) Can anyone suggest how to do it in proc sql.?

Re: How to format date values in Proc SQL

LinusH — Thu, 01 Oct 2015 11:13:25 GMT

FORMAT= as a column option in either SELECT or CREATE statement,

Re: How to format date values in Proc SQL

Steelers_In_DC — Thu, 01 Oct 2015 13:30:18 GMT

Here you go:

data have;
informat date mmddyy10.;
format date mmddyy10.;
input date;
cards;
10/01/2015
;
run;

proc sql;
create table want as
select date format = date9.
from have;

Re: How to format date values in Proc SQL

Reeza — Thu, 01 Oct 2015 14:23:10 GMT

Is it a character or SAS date value?

Re: How to format date values in Proc SQL

PGStats — Tue, 28 Mar 2017 12:07:57 GMT

Depends whether your dates are like a, b or c in the following example

data test;
  a = 201506; /* YYYYMM as a number */
  b = '01JUN2015'd; /* SAS date value with YYYYMM format */
  format b yymmn6.;
  c = "201506"; /* char version of the YYYYMM date */
run;

proc print; run;

proc sql;
select 
    mdy(mod(a, 100), 1, int(a/100)) as date_a format=yymmdd6.,
    b as date_b format=yymmdd6.,
    input(c, yymmn6.) as date_c  format=yymmdd6.
from test;
quit;

Result: