topic Re: Getting value from first column first row without knowing the variable name? in SAS Procedures

Getting value from first column first row without knowing the variable name?

jerry898969 — Thu, 30 Jun 2011 15:52:03 GMT

I need to get the value of the first variable first row of a data set without knowing the variable name.

The reason for this is I have to create a macro that will loop through many datasets and look at the first variable first row's value. Each data set has a different name for the first variable.

Any help would be appreciated.

Thank you

Getting value from first column first row without knowing the variable name?

NickR — Thu, 30 Jun 2011 17:15:24 GMT

proc sql noprint;

select name into :firstvar from dictionary.columns where libname='SASHELP' and memname='CLASS'

and varnum=1;

quit;

proc print data=sashelp.class (obs=1);

var &firstvar;

run;

Re: Getting value from first column first row without knowing the variable name?

data_null__ — Thu, 30 Jun 2011 17:36:23 GMT

A slight variation on NickR's method. This gets a list of MEMNAMEs and variables NAMEs you can create a data table to run a macro or other code generator.

proc sql;

select name, memname

from dictionary.columns

where libname eq 'SASHELP' and memtype in('DATA') and varnum eq 1

;

quit;

run;

Re: Getting value from first column first row without knowing the variable name?

Ksharp — Fri, 01 Jul 2011 08:49:47 GMT

Hi. I found this can be achieve by proc sql. It is very interesting, but there a Warning message

in log , If you do not care about it.

proc sql noprint;
 select *
  into : first_value1 
   from sashelp.class;

 select *
  into : first_value2
   from sashelp.air;

quit;
%put &first_value1 &first_value2;






proc sql noprint;
 select *
  into : first_value1 
   from sashelp.class;

 select *
  into : first_value2
   from sashelp.air;

quit;
%put &first_value1 &first_value2;

Ksharp

Re: Getting value from first column first row without knowing the variable name?

Howles — Mon, 04 Jul 2011 01:18:55 GMT

Here's a way using the DATA step:

data _null_ ;

set sashelp.shoes ;

length __name $32 ;

call vnext(__name);

r1c1 = vvalue(__name) ;

put r1c1= ;

stop ;

run ;

jerry898969 wrote:

I need to get the value of the first variable first row of a data set without knowing the variable name.

The reason for this is I have to create a macro that will loop through many datasets and look at the first variable first row's value. Each data set has a different name for the first variable.

Any help would be appreciated.

Thank you

Re: Getting value from first column first row without knowing the variable name?

Ksharp — Mon, 04 Jul 2011 06:04:32 GMT

H. Howles

Maybe it should be vvaluex()?

Ksharp