topic Re: How to identify repeating characters in the string. in SAS Procedures

How to identify repeating characters in the string.

pr1 — Thu, 26 Mar 2015 14:30:21 GMT

Hello, I have a 9 character data field and I need to identify if any 3 of the consecutive characters in that string are the same. Any ideas on how to achieve this?

Thanks.

Pramodini

Re: How to identify repeating characters in the string.

Jagadishkatam — Thu, 26 Mar 2015 14:36:01 GMT

could you please give an example data

Re: How to identify repeating characters in the string.

ballardw — Thu, 26 Mar 2015 14:42:32 GMT

Does case matter? For example does "aAa" count as the "same character"? Are any of the characters special characters such as punctuation, ()!@#$%^&*-_=+/><\|][{}

Do multiple spaces count?

Re: How to identify repeating characters in the string.

Astounding — Thu, 26 Mar 2015 14:46:05 GMT

Assuming you want an exact match on any possible character, here is a way:

data want;

set have;

do i=1 to 7 until (flag=1);

if substr(var, i, 1) = substr(var, i+1, 1) = substr(var, i+2, 1) then flag=1;

end;

run;

Good luck.

Re: How to identify repeating characters in the string.

Jagadishkatam — Thu, 26 Mar 2015 14:50:00 GMT

Also you may try,

data have;

char='a b b a c c c';

do i = 1 to 10;

new2=scan(char,i,' ');

output;

end;

run;

data want;

set have;

by notsorted new2;

retain count 0;

if first.new2 then count=1;

else count+1;

if last.new2 and count=3 and new2 ne '';

run;

Thanks,
Jag

Re: How to identify repeating characters in the string.

pr1 — Thu, 26 Mar 2015 15:16:22 GMT

THANK YOU all!!! This works.

Appreciate all the help.

Re: How to identify repeating characters in the string.

Haikuo — Thu, 26 Mar 2015 15:18:43 GMT

Come on, there has to be PRX solution for this

data test;

infile cards truncover;

input str $ 100.;

flag=prxmatch('m/(\S)\1{2}/o',str)>0;

cards;

adlsfkj888adklfj

alkjahfkldjhklajdhfklj

akljsd******alkdfkj

;

Re: How to identify repeating characters in the string.

FriedEgg — Fri, 27 Mar 2015 00:04:00 GMT

Here is an explaination of the regular expression:

(\S)\1{2}

Match the regular expression below and capture its match into backreference number 1 «(\S)»

Match a single character that is a “non-whitespace character” «\S»

Match the same text as most recently matched by capturing group number 1 «\1{2}»

Exactly 2 times «{2}»

The m before the starting delimiter (/) I would say is not relevant here.

The o after the ending delimiter (/) is an optimizer that tells SAS the expression can be held and reused without recompilation throughout the execution of the data step.

See the documentation:

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002295977.htm

Compiling a Perl Regular Expression

If perl-regular-expression is a constant or if it uses the /o option, the Perl regular expression is compiled only once. Successive calls to PRXPARSE will not cause a recompile, but will return the regular-expression-id for the regular expression that was already compiled. This behavior simplifies the code because you do not need to use an initialization block (IF _N_ =1) to initialize Perl regular expressions.
Note:   If you have a Perl regular expression that is a constant, or if the regular expression uses the /o option, then calling PRXFREE to free the memory allocation results in the need to recompile the regular expression the next time that it is called by PRXPARSE.
The compile-once behavior occurs when you use PRXPARSE in a DATA step. For all other uses, the perl-regular-expression is recompiled for each call to PRXPARSE.

Re: How to identify repeating characters in the string.

naveen_srini — Fri, 27 Mar 2015 16:45:45 GMT

Hi A small request and sorry it's off topic, I have noticed you using APPC functions extremely well as opposed many other major contributors. Can you please provide me a link documentation that explains pretty much well in detail for that one too? I'd appreciate it so much. Thanks.

Re: How to identify repeating characters in the string.

PGStats — Fri, 27 Mar 2015 17:39:37 GMT

Does anyone know if the "compile-once" behavior also occurs in SQL expressions?

Re: How to identify repeating characters in the string.

FriedEgg — Fri, 27 Mar 2015 19:51:47 GMT

PG, it does have a similar behavior in SQL

Re: How to identify repeating characters in the string.

FriedEgg — Fri, 27 Mar 2015 19:53:25 GMT

naveen_srini,

Rather than taking this post off-topic, it would be more prudent to post a new question. I will gladly answer you to the best that I can, as will others, I'm sure.

Re: How to identify repeating characters in the string.

PGStats — Sat, 28 Mar 2015 16:53:20 GMT

Thank you Matt!

Re: How to identify repeating characters in the string.

BOBSAS — Sun, 29 Mar 2015 01:45:49 GMT

Hey. I was getting the correct result but I'm getting a warning too. So I modified a bit and tried but can't figure it out.

Would it be possible for you to tell me why I am getting the below warning and how can I fix it.

Thanks.

data have;

var="Sasexampleee";output;

var="Sasexampplee";output;

var="Sasexammmppl";output;

var="Sasexampl";output;

run;

data want;

set have;

leng=length(var);

do i=1 to leng;

if substr(var, i, 1) = substr(var, i+1, 1) = substr(var, i+2, 1) then flag=1;

end;

run;

NOTE: Invalid second argument to function SUBSTR at line 27 column 52.

NOTE: Invalid second argument to function SUBSTR at line 27 column 30.

NOTE: Invalid second argument to function SUBSTR at line 27 column 52.

var=Sasexampplee leng=12 i=13 flag=. _ERROR_=1 _N_=2

NOTE: Invalid second argument to function SUBSTR at line 27 column 52.

var=Sasexamplee leng=11 i=12 flag=. _ERROR_=1 _N_=4

NOTE: There were 4 observations read from the data set WORK.HAVE.

Re: How to identify repeating characters in the string.

PGStats — Sun, 29 Mar 2015 02:02:47 GMT

When i = leng in your loop, you look at character position i+2 which is beyond the length of the variable. You can simply stop the loop sooner:

data want;

set have;

leng=length(var) - 2;

do i=1 to leng;

if substr(var, i, 1) = substr(var, i+1, 1) = substr(var, i+2, 1) then flag=1;

end;

run;

Re: How to identify repeating characters in the string.

BOBSAS — Sun, 29 Mar 2015 02:10:21 GMT

Worked well. Thanks.

Re: How to identify repeating characters in the string.

pr1 — Thu, 02 Apr 2015 18:31:11 GMT

This code is giving me false positive.

I have character data that has ID Numbers. It is 9 character long string and has numbers as char data from 0 to 9. I am trying to identify if 5 or more consecutive characters are the same. If yes, then I will create a flag.

I have this code below. It works most of the time but also gives me false positive. For example, it will pick up something like 121341111 – where the ‘1’ is within the string 5 or more times.

I want to identify only if a character is present consecutively 5 or more times. 121341111 should not be flagged 1 repeated consecutively only 4 times.

Any idea?

data want(drop = i) ;

set have ;

length ssn_char ssn_rept_chars $9;

ssn_char = ssn;

do i=1 to 6 until (flag=1);

if substr(ssn_char, i, 1) = substr(ssn_char, i+1, 1) = substr(ssn_char, i+2, 1) = substr(ssn_char, i+3, 1)

then flag=1;

if flag = 1 then ssn_rept_chars = ssn_char;

end;

run;