topic how to count number of observations in SAS Procedures

how to count number of observations

igbuzov — Thu, 18 Jun 2015 18:33:26 GMT

hello

I have this dataset:

data new;

infile datalines;

input ID $ Name $ Nationality $ Price;

datalines;

01 Hans Y 130

02 Pierre Y 100

03 Marko N 80

04 Ivan N 95

05 John Y 120

06 Ana N 75

07 Petra N 45

;

I would like, as result to have new dataset with two new variables which would count the number of Nationality(Y) and Nationality(N), something like this

proc print data=result;

run;

obs Number_of_Y Number_of_N

I got this by using proc sql, created two views, based on them i created new tabel named result. I would like to know how to do this using data step programming or some better way using proc sql queries.

Thank you

Re: how to count number of observations

dcruik — Thu, 18 Jun 2015 20:10:51 GMT

Here's a way to do it with PROC SQL, not sure if you want the "obs" field in your result data set or not. Hope this is what you're looking for!

data have;

input ID $ Name $ Nationality $ Price;

datalines;

01 Hans Y 130

02 Pierre Y 100

03 Marko N 80

04 Ivan N 95

05 John Y 120

06 Ana N 75

07 Petra N 45

;

run;

proc sql;

create table want as

select 1 as obs,

sum(case when Nationality="Y" then 1

Else 0 end) as Number_of_Y,

sum(case when Nationality="N" then 1

Else 0 end) as Number_of_N

from have;

quit;

Re: how to count number of observations

PGStats — Thu, 18 Jun 2015 20:14:45 GMT

Alternative SQL query :

proc sql;

select

sum(nationality="Y") as Number_of_Y,

sum(nationality="N") as Number_of_N

from new;

quit;

Re: how to count number of observations

slchen — Thu, 18 Jun 2015 20:46:02 GMT

proc freq data=new;

table Nationality;

output out=temp;

run;

proc transpose data=temp(drop=percent) prefix=Number_of_ out=want(drop=_:);

id nationality;

run;

Re: how to count number of observations

igbuzov — Thu, 18 Jun 2015 22:39:34 GMT

Thanks guys for your help 🙂