topic Re: Convert of Best 12. to YYMMDDN8. in SAS Procedures

Convert of Best 12. to YYMMDDN8.

george_gt — Thu, 16 Jul 2015 09:53:40 GMT

Does anyone know how to convert number format into date format? For example, the following shows what my data looks like:

Date

20060306

20040727

20040407

20010423

All of data is shown as the number format BEST12. Informat 12. I want to convert them into these format YYMMDDN8. Informat YYMMDD6. in order to do a match afterwards. Could anyone tell me how to do it? Many Thanks in advance.

george

Re: Convert of Best 12. to YYMMDDN8.

Loko — Thu, 16 Jul 2015 11:38:21 GMT

hello,

data have;

input Date;

datalines;

20060306

20040727

20040407

20010423

;

run;

data want;

set have;

date_c=put(date,8.);

date_n=input(date_c,yymmdd8.);

format date_n yymmddn8.;

run;

Re: Convert of Best 12. to YYMMDDN8.

Steelers_In_DC — Thu, 16 Jul 2015 11:51:09 GMT

data have;

infile cards;

input date;

format date best12.;

cards;

20060306

20040727

20040407

20010423

;

run;

data want;

format date2 yymmddn8.;

set have;

date2 = input(put(date,8.),yymmdd8.);

run;

Re: Convert of Best 12. to YYMMDDN8.

RW9 — Thu, 16 Jul 2015 12:11:18 GMT

You could just stop at the format statement (same test data):

data want;

set have;

format date yymmdd8.;

run;

Re: Convert of Best 12. to YYMMDDN8.

data_null__ — Thu, 16 Jul 2015 12:57:43 GMT

Are you sure? I don't think associating YYMMDD8 with a numeric variable that does not contain a "SAS Date" will produce the correct result. You have to read the "date string" using the proper date INFORMAT.

data have;
   input date;
   x = date;
   format date yymmdd8.; 
   cards; 
20060306
20040727
20040407
20010423
;;;;
   run; 
proc print; 
   run; 

data todate;
   set have;
   sasdate = input(put(date,8.),yymmdd8.);
   format date;
   format sasdate yymmddn8.; 
   run; 
proc print; 
   run; 
proc print; 
   format _all_;
   run;

Re: Convert of Best 12. to YYMMDDN8.

RW9 — Thu, 16 Jul 2015 13:17:07 GMT

Yes, you are quite correct. Ignore my post.