topic Re: Proc Freq--All inclusive table in SAS Procedures

Proc Freq--All inclusive table

Greek — Tue, 14 Jul 2015 18:01:52 GMT

Good afternoon,

I have a question related to the tabular output of proc freq.

Let's say that I have the following survey question:

Do you like politics?

a) Yes

b) No

c) Maybe

d) Uncertain

In the event that one of the 4 options gets selected by nobody (say d), Proc freq will give me the following table (Code created for your convenience):

data example;

input answer $ @@;

datalines;

Yes Yes Yes Yes Yes No Maybe Maybe Maybe No No Yes

run;

proc freq data=example;

run;

answer	Frequency	Percent	Cumulative Frequency	Cumulative Percent
Maybe	3	25	3	25
No	3	25	6	50
Yes	6	50	12	100

While I would like the missing 'd. Uncertain' to be recorded:

answer	Frequency	Percent	Cumulative Frequency	Cumulative Percent
Maybe	3	25	3	25
Uncertain	0	0	3	25
No	3	25	6	50
Yes	6	50	12	100

Do you know how can I make proc freq output the second table? If proc freq can't do it, do you have a different procedure in mind that can?

Thank you

Re: Proc Freq--All inclusive table

Ksharp — Wed, 15 Jul 2015 14:13:27 GMT

Simple Data Step ?

Code: Program

data example;
input answer $ @@;
datalines;
Yes Yes Yes Yes Yes No Maybe Maybe Maybe No No Yes
run;
 
ods output OneWayFreqs=temp;
proc freq data=example ;
 tables answer/ cumcol;
run;
data want;
length answer $ 20;
 set temp;
 output;
 if _n_ eq 1 then do;
  answer='Uncertain';
  Frequency=0;Percent=0;output;
 end;
 drop Table F_answer;
run;

Xia Keshan

Re: Proc Freq--All inclusive table

Greek — Mon, 20 Jul 2015 17:41:09 GMT

Hello Xia,

Thank you very much for your response. I was hoping for something less manual as I need to produce a large series of frequency tables and I am using macros, but this is certainly helpful. I will use it in a case-by-case basis.

Re: Proc Freq--All inclusive table

Reeza — Mon, 20 Jul 2015 17:55:17 GMT

Look into proc tabulate and PRELOADFMT

There are probably more clear examples than this one, but its the documentation

25400 - Use of PRELOADFMT with PROC TABULATE

No matter what, you need some table or somewhere that has the full list of all options.

Re: Proc Freq--All inclusive table

data_null__ — Mon, 20 Jul 2015 19:34:50 GMT

data classdata;
   input answer :$10.; 
   cards; 
Yes
No
Maybe
Uncertain
;;;; 
   run; 
proc print; 
   run; 
data example;
   input answer :$10. @@;
   datalines; 
   Yes Yes Yes Yes Yes No Maybe Maybe Maybe No No Yes
   run; 
proc print; 
   run; 
proc summary data=example nway classdata=classdata order=data;
   class answer;
   output out=freq(drop=_type_);
   run; 
proc print; 
   run; 
proc freq data=freq order=data;
   tables answer;
   weight _freq_ / zeros; 
   run;

Re: Proc Freq--All inclusive table

Greek — Tue, 21 Jul 2015 19:52:30 GMT

Thank you all so much!