topic Re: appending text files in SAS Procedures

appending text files

Tal — Thu, 22 Jan 2015 02:51:48 GMT

Hi,

I have one external text file that i like to append to another but i dont like to read them in into a dataset as the files have many variables. And they both have the same layout. How do i do that?

Re: appending text files

Reeza — Thu, 22 Jan 2015 03:01:51 GMT

Use your OS commands - in Unix its cat, may be in powershell as well.

Do you have headers you need to deal with or is it straight appending of the two text files.

Re: appending text files

Kurt_Bremser — Thu, 22 Jan 2015 06:37:43 GMT

filename infile ("path_to_file_a","path_to_file_b") options;

if you want to read them in one step.

Otherwise, use the X statement or call system to do it with a suiting OS command, as Reeza suggested.

Re: appending text files

BrunoMueller — Thu, 22 Jan 2015 10:36:31 GMT

You can make use of the MOD option of the FILE statement, this will allow you to add new records to an existing external file.

see this sample code, that illustrates this:

*
* create base file
*;
filename xbase temp; 

data _null_; 
  set sashelp.class;
  where age lt 14; 
  file xbase dsd dlm=","; 
  put name age sex height weight;
run; 

*
* create append file
*;
filename xapp temp; 

data _null_; 
  set sashelp.class;
  where age ge 14; 
  file xapp dsd dlm=","; 
  put name age sex height weight;
run; 

*
* use the base file with the MOD option, so
* that new reords are appended to the file
*;
data _null_; 
  file xbase mod; 
  infile xapp;
  input; 
  put _infile_; 
run; 

*
* verify the result
*;
data _null_; 
  infile xbase;
  input; 
  putlog _infile_;
run;

Re: appending text files

Tal — Fri, 20 Feb 2015 03:43:46 GMT

Thx guys. The cat command works perfectly