topic Re: want to keep observations if variable x equals to something in SAS Procedures

want to keep observations if variable x equals to something

aarony — Wed, 16 Apr 2014 19:50:13 GMT

hi i have a variable country code (below)

data sortedbase2;

set sortedbase;

length countrycode $2;

countrycode = substr(left(ISIN),1,2); /* left-align ISIN and extract 2 characters starting from position 1 of ‘ISIN’ */

run;

and I want to keep them is country code equals both HK and CN. how may i code this?

-----------------------

i get an error for somereason and sas creates a variable HK and CN if ''

*keep the ones with HK/CN;

data sortedbase3;

set sortedbase2;

if countrycode ne CN then delete;

run;

Re: want to keep observations if variable x equals to something

Linlin — Wed, 16 Apr 2014 20:24:32 GMT

you need to use " " when working with character variables:

changing

if countrycode ne CN then delete;

if countrycode ne 'CN' then delete ;

Re: want to keep observations if variable x equals to something

PaigeMiller — Wed, 16 Apr 2014 20:25:59 GMT

and I want to keep them is country code equals both HK and CN

Do you perhaps mean "and I want to keep them if country code equals either HK or CN"? Because based on what you wrote, I don't think country code can equal both HK and CN

If so, then this should work

data sortedbase2;

set sortedbase;

length countrycode $2;

countrycode = substr(left(ISIN),1,2); /* left-align ISIN and extract 2 characters starting from position 1 of ‘ISIN’ */

if countrycode="HK" or countrycode="CN" then output;

run;

Re: want to keep observations if variable x equals to something

ballardw — Wed, 16 Apr 2014 20:34:07 GMT

And just in case you end up wanting to use longer lists of values the IN operator is helpful:

if countrycode in ("HK", "CN") then output;

Add items as needed instead of a multitude of If this or that or somethelse or yet some other value constructs.

Re: want to keep observations if variable x equals to something

Astounding — Wed, 16 Apr 2014 20:46:41 GMT

In addition to all the other suggestions, you don't need to actually create COUNTRYCODE. You could use:

data sortedbase2;

set sortedbase;

if left(isin) in: ('HK', 'CN') then output;

run;

The in: comparison will use fewer characters of ISIN instead of the whole string.

Re: want to keep observations if variable x equals to something

SKK — Thu, 17 Apr 2014 04:58:40 GMT

Here's my try with Proc SQL,

PROC SQL;

CREATE TABLE WANT AS SELECT * FROM sortedbase

WHERE substr(left(UPCASE(ISIN)),1,2) in ("HK","CN");

QUIT;

Re: want to keep observations if variable x equals to something

TarunKumar — Thu, 17 Apr 2014 06:53:57 GMT

data sortedbase2;

set sortedbase;

length countrycode $2;

if substr(compress(upcase(ISIN)),1,2) in ('HK','CN');

countrycode = substr(compress(upcase(ISIN)),1,2);

run;

Re: want to keep observations if variable x equals to something

RW9 — Thu, 17 Apr 2014 09:12:23 GMT

data sortedbase2;

set sortedbase;

where substr(left(ISIN),1,2) in ("HK","CN");

run;

Re: want to keep observations if variable x equals to something

MikeZdeb — Thu, 17 Apr 2014 15:06:38 GMT

hi ... the more the merrier ...

data sortedbase3;

array check(2) $2 _temporary_ ("HK" "CN");

set sortedbase2;

if countrycode in check;

run;