topic Re: Removing row headers in tabulate in SAS Procedures

Removing row headers in tabulate

BruceBrad — Fri, 10 Oct 2014 06:07:28 GMT

(Related to - but not the same as my other question on headers).

I have

data test;

input v1 v2 v3;

cards;

1 1 1

2 2 4

3 4 10

;

proc tabulate;

class v1 v2;

var v3;

label v1=''; /* two single quotes */

label v3='';

table min*v3*v1,v2;

run;

The output I get is in the attached screenshot. In short, I get single quotes appearing for the labels for v1 and v2. How do I remove them altogether? I'm using 9.4. (If use ' ' (a space between the quotes) the variable names appear instead. I get the same result if I use double quotes).

Re: Removing row headers in tabulate

Patrick — Fri, 10 Oct 2014 07:33:00 GMT

Have a blank between the quotes.

Re: Removing row headers in tabulate

BruceBrad — Fri, 10 Oct 2014 09:20:13 GMT

Tried that. If I do that, I get the variable name appearing.

Re: Removing row headers in tabulate

RW9 — Fri, 10 Oct 2014 10:32:45 GMT

Well, funnily enough this seems to work:

data test;

input v1 v2 v3;

cards;

1 1 1

2 2 4

3 4 10

;

run;

ods escapechar "^";

proc tabulate;

class v1 v2;

var v3;

label v1="^{subscript }"; /* two single quotes */

label v3="^{superscript }";

table min*v3*v1,v2;

run;

Not ideal I know (I personally don't use tabulate). You could also just output to a dataset:

proc tabulate out=xyz;

...

Then use proc report to generate the output required.

Re: Removing row headers in tabulate

data_null__ — Fri, 10 Oct 2014 11:18:01 GMT

I would use the nob-breaking space byte(160) 'a0'x It may be output destination dependent but it seems that something with space in the name should print as "blank".

data test;
input v1 v2 v3;
cards; 
1 1 1
2 2 4
3 4 10
; 
proc tabulate; 
  class v1 v2;
  var v3;
  label v1='a0'x;  
  label v3='a0'x; 
  table min*v3*v1,v2;
  run;

Re: Removing row headers in tabulate

Ksharp — Fri, 10 Oct 2014 12:02:41 GMT

data test;
input v1 v2 v3;
cards; 
1 1 1
2 2 4
3 4 10
; 
proc tabulate; 
  class v1 v2;
  var v3;
  table min*v3=' '*v1=' ',v2;
  run;

Xia Keshan

Re: Removing row headers in tabulate

data_null__ — Fri, 10 Oct 2014 12:17:06 GMT

Ksharp wrote:

data test;
input v1 v2 v3;
cards; 
1 1 1
2 2 4
3 4 10
; 
proc tabulate; 
  class v1 v2;
  var v3;
  table min*v3=' '*v1=' ',v2;
  run;




Xia Keshan

This should be the preferred method as it removes the "label" row produce by non-breaking space

Re: Removing row headers in tabulate

ballardw — Fri, 10 Oct 2014 18:09:16 GMT

Or instead of relying on label:

proc tabulate;

class v1 v2;

var v3;

table v3='' * v1='',v2*sum='';

run;

Single quotes with no space to override. Since V3 is a VAR it want a summary statistic row header which will still appear as blank.

Re: Removing row headers in tabulate

BruceBrad — Fri, 10 Oct 2014 23:06:46 GMT

Thanks all. The responses which suggest using the within table statement =' ' formatting work (with or without the space in between). I thought I had tried this, but obviously not.