topic Re: proc append - keep identifier in SAS Procedures

proc append - keep identifier

bollibompa — Mon, 17 Feb 2014 09:10:01 GMT

I have a library with data from four years (2010-2014) each dataset includes two variables: id and source

library:

data_2010

data_2011

data_2012

data_2013

I now want to append these years and in the append step (or what step the best for doing this...) create a variable that tells you which year the data comes from. Like this:

id source year (new)

1 a 2010

2 a 2010

1 b 2011

2 b 2011

and so on...

I'd rather not create the variable in each dataset because they are huge

Is it possible to create this variable in the append step?

/Thomas

Re: proc append - keep identifier

LinusH — Mon, 17 Feb 2014 10:50:25 GMT

You could create views which contains the years, have proc append read from those instead.

Re: proc append - keep identifier

BrunoMueller — Mon, 17 Feb 2014 13:05:17 GMT

Hi bollibompa

See code sample below, it uses some techniques available since SAS9.2 where you can specify data sets lists and the INDSNAME= option on the SET statement.

Bruno

data data_2010 data_2011  data_2012 data_2013;
  do id = 1 to 5; 
    source = char("ABCDEFG", id);
    output; 
  end; 
run; 

data data_want;
  set data_2010 - data_2013 indsname=_dsname;
  length year $ 4; 
  year = scan(_dsname, 2, "_");
run;

Re: proc append - keep identifier

Tom — Mon, 17 Feb 2014 14:51:56 GMT

INDSNAME option on the SET statement is what you want.

But you might also want to look into using a BY statement with your SET so that the final dataset will still be sorted by ID. And if you order the datasets in the SET statement properly then the final dataset will also be sorted by YEAR within ID.

data want ;

length indsname $41 ;

set data_2010-data_2013 indsname=indsname ;

by id source ;

year = input(scan(idsname,-1,'_'),4.);

run;

Re: proc append - keep identifier

stat_sas — Mon, 17 Feb 2014 16:23:54 GMT

How about this one

proc sql;

insert into all

select id,source, 2010 as source_file

from data_2010

UNION

select id,source, 2011 as source_file

from data_2011

UNION

select id,source, 2012 as source_file

from data_2012

UNION

select id,source, 2013 as source_file

from data_2013;

quit;

Re: proc append - keep identifier

bollibompa — Wed, 19 Feb 2014 10:14:34 GMT

Thank you all for quick replies!

INDSNAME was exactly what I was looking for, works perfect!

Thomas

Re: proc append - keep identifier

ArunSingapore — Thu, 14 Feb 2019 16:25:53 GMT

Hi,

I am reading huge xml files using xmlv2 libname and xmlmapper file.

After reading the each file, I need to add a source filename to the output dataset.

I can not use INDSNAME option because I must use PROC APPEND.

Because my source file has missing columns or additional new columns every time.

This can be done only using PROC APPEND with FORCE option.

Hence kindly guide me how can I add a new column in PROC APPEND?

Thanks

Arun