topic Re: Change All Character variables' length in SAS Procedures

Change All Character variables' length

need_sas_help — Mon, 06 Oct 2014 18:55:38 GMT

I have a dataset with 200 character variables. all of those characters variables' lengths are between 5 to 10. Is there anyway to change the length of all of these character variables' to $40 in a short efficent way?( i know how to chnage the length or attribute, before the set statmment, but it will create a very long ugly coding)

Thank you a lot

Re: Change All Character variables' length

Haikuo — Mon, 06 Oct 2014 19:06:13 GMT

I suppose you will need some codgen:

proc sql;

select name into :vname separated by ' ' from dictionary.columns where LIBNAME='SASHELP' AND MEMNAME='CLASS' AND type='char';

quit;

data want;

length &vname $ 40;

set sashelp.class;

run;

Haikuo

Re: Change All Character variables' length

need_sas_help — Mon, 06 Oct 2014 19:26:00 GMT

sorry did not understand how to relate your codes with my dataset.

Re: Change All Character variables' length

Haikuo — Mon, 06 Oct 2014 19:34:36 GMT

proc sql;

select name into :vname separated by ' ' from dictionary.columns where LIBNAME='YOURLIB' /*NEED TO BE CAPPED*/ AND MEMNAME='YOURDATASET'/*NEED TO BE CAPPED*/ AND type='char';

quit;

data want;

length &vname $ 40;

set YOURLIB.YOURDATASET;

run;

Re: Change All Character variables' length

need_sas_help — Mon, 06 Oct 2014 19:45:31 GMT

Hi Hai,

Please find the log as below (bold and underlined) : SQL staement do not produce any rows. I am sure you are correct But i am missing something.

690 proc sql;

691 select name into :vname separated by ' ' from dictionary.columns where LIBNAME='YOURLIB'

691! /*NEED TO BE CAPPED*/ AND MEMNAME='YOURDATASET'/*NEED TO BE CAPPED*/ AND type='char';

NOTE: No rows were selected.

692 quit;

NOTE: PROCEDURE SQL used (Total process time):

real time 0.14 seconds

cpu time 0.01 seconds

693

694

695 data want;

696 length &vname $ 40;

697 set tto;

698 run;

NOTE: Variable Name is uninitialized.

NOTE: Variable Sex is uninitialized.

NOTE: There were 12 observations read from the data set WORK.TTO.

NOTE: The data set WORK.WANT has 12 observations and 26 variables.

NOTE: DATA statement used (Total process time):

real time 0.00 seconds

cpu time 0.00 seconds

Re: Change All Character variables' length

Haikuo — Mon, 06 Oct 2014 19:48:51 GMT

proc sql;

select name into :vname separated by ' ' from dictionary.columns where LIBNAME='WORK' /*NEED TO BE CAPPED*/ AND MEMNAME='TTO'/*NEED TO BE CAPPED*/ AND type='char';

quit;

data want;

length &vname $ 40;

set TTO;

run;

Good luck,

Haikuo

Re: Change All Character variables' length

need_sas_help — Mon, 06 Oct 2014 19:52:46 GMT

Thanks Haikuo. It workd. Thanks a lot

Re: Change All Character variables' length

Ksharp — Tue, 07 Oct 2014 14:09:25 GMT

HaiKuo's code will overwrite the table again , that would not be an efficient way .

data class;
 set sashelp.class;
run;
 proc sql;
     select catx(' ',name,'char(40)') into :vname separated by ',' from dictionary.columns where LIBNAME='SASHELP' AND MEMNAME='CLASS' AND type='char';
alter table class
modify &vname ;
quit;

Xia Keshan