topic Re: deal with a bunch of variables ending with some common letter in SAS Procedures

deal with a bunch of variables ending with some common letter

Sunny_Sun — Wed, 07 Jan 2015 20:33:05 GMT

Hi,

I need to drop a bunch of variables ending with either _xx or _xy. How to do it in SAS? the colon ":" seems only working for starting letters.

Thanks in advance.

Thanks,

Sunny

Re: deal with a bunch of variables ending with some common letter

Loko — Wed, 07 Jan 2015 20:37:23 GMT

hello,

something like this :

proc sql noprint;
select name into :vars separated by ' ' from sashelp.vcolumn
where memname='CLASS' and libname='SASHELP' AND name like '%e';
quit;

%put &vars;

data want;
set sashelp.class (drop=&vars) ;
run;

Re: deal with a bunch of variables ending with some common letter

Haikuo — Wed, 07 Jan 2015 20:47:50 GMT

data test;

a=1;

b=1;

_xx=2;

_xy=3;

run;

proc sql;

select distinct name into :name separated by ' ' from dictionary.columns where libname='WORK' AND MEMNAME='TEST' AND prxmatch('/(_xx|_xy)$/io',TRIM(name))=0;

QUIT;

data want;

set test (keep=&name);

run;

Re: deal with a bunch of variables ending with some common letter

Sunny_Sun — Wed, 07 Jan 2015 20:52:52 GMT

Many thanks kuo!

Re: deal with a bunch of variables ending with some common letter

Sunny_Sun — Wed, 07 Jan 2015 20:53:28 GMT

Many thanks Loko!

Re: deal with a bunch of variables ending with some common letter

Ksharp — Thu, 08 Jan 2015 04:20:14 GMT

Learn how to use escape character.

data test;

a=1;

b=1;

_xx=2; xx=22;

_xy=3; yy=33;

run;

proc sql;

select distinct name into : name separated by ' '

from dictionary.columns

where libname='WORK' AND MEMNAME='TEST' AND

(lowcase(name) like '%~_xx' escape '~' or

lowcase(name) like '%~_xy' escape '~' );

QUIT;

data want;

set test (drop=&name);

run;

Xia Keshan