topic Re: Skipping lines with DATALINES; in SAS Procedures

Skipping lines with DATALINES;

JonS — Tue, 17 Feb 2015 14:28:36 GMT

Hello,

I have the following DATA step which should read in 2 observations with 3 variables:

data want;

input Name1 $ Num1 Name2 $10.;

datalines;

testing

444

small

33321

asdfasdfas

;

run;

The $10. informat is necessary to read in all of "asdfasdfas". This gives the following output:

Obs Name1 Num1 Name2

1 testing 444

2 dd .

3 33321 .

If I use $ instead of $10. the data will be correct except it cuts off asdfasdfas at the 8 characters, as is the default. I know that SAS reads datalines with padded zeros, but why does the informat cause "dd" to not be read correctly? This issue does not happen if I store the datalines in the txt file and read that data in with an INFILE statement.

Thanks!

Re: Skipping lines with DATALINES;

RW9 — Tue, 17 Feb 2015 14:46:59 GMT

Pop a length statement in first, then remove the 10 from the input. Also, would recommend that approach, i.e. what happens with missing? A suggestion would be to go with CSV.

data want;

length name1 $20 num1 8 name2 $20;

input Name1 $ Num1 Name2 $;

datalines;

testing

444

small

33321

asdfasdfas

;

run;

Re: Skipping lines with DATALINES;

JonS — Tue, 17 Feb 2015 14:56:53 GMT

That's interesting that the LENGTH statement fixes this. My question is more about why doesn't it work than how to fix it.

What is SAS doing that makes my code not work correctly? Why does the LENGTH statement fix it? Does it have something to do with how the INFORMAT controls the column pointer?

Thanks!

Re: Skipping lines with DATALINES;

data_null__ — Tue, 17 Feb 2015 14:57:19 GMT

$10. changes the INPUT "type" from LIST to FORMATTED and that is the problem. You need to use : modifier to allow use of and INFORMAT and stay in LIST input mode.

input Name1 $ Num1 Name2 : $10.;

Re: Skipping lines with DATALINES;

Tom — Tue, 17 Feb 2015 15:08:45 GMT

The LENGTH statement is not what fixed it. It was the removal of the hardcoded $10. informat.

The LENGTH statement just lets you EXPLICITLY set the length/type for your variables rather than forcing SAS to guess what you want from your other statements.

Re: Skipping lines with DATALINES;

RW9 — Tue, 17 Feb 2015 15:14:56 GMT

data _null_; and Tom have answered the question, however its another reason to be quite clear in the code and not let SAS do guess work behind the scenes.

Re: Skipping lines with DATALINES;

JonS — Tue, 17 Feb 2015 15:19:40 GMT

I think I understand now. Specifying informats in the INPUT statement allows you to specify an informat along with a column input style. The first two variables use list input style so they stop being read once it hits the end of the line. Since the last variable had a hardcoded informat, it didn't skip to the next line and instead read the hidden padded zeroes after the 444.

Re: Skipping lines with DATALINES;

Loko — Tue, 17 Feb 2015 15:22:02 GMT

Hello,

Continuing a little bit data _null_ explanation , when you have switched to FORMATTED INPUT , SAS reads from where the pointer is therefore it does not scan for the next value as the case when reading data with LIST INPUT.

You may find these links useful:

http://support.sas.com/documentation/cdl/en/lrcon/62955/HTML/default/viewer.htm#a003209907.htm

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000144370.htm