topic Re: Help concerning mail generated from SAS in SAS Procedures

Help concerning mail generated from SAS

JoeBill — Tue, 03 Dec 2013 08:41:15 GMT

Hi Guys, hope you can help with this one:

I'm generating a SAS mail, which is supposed to distribute a mail with exchange rate fluctuations to a group of receivers. However, the procedure does not "print" the data table to the mail. Somehow, the procedure genereates the mail destributes it only with a text, and afterworth creates the table, that was supposed the be part of the mail.

Can anyone help me with this?

My code can be seen below:

FILENAME outbox EMAIL "xxx@xxx.xx";

DATA _NULL_;

FILE outbox

/* Overrides value in filename statement */

to=("xxx@xxx.xx")

cc=("")

subject="return %SYSFUNC(putn(&ReportDate,DDMMYY10.)) and daily prices %SYSFUNC(putn(&LastDate_FT,DDMMYY10.))";

ods listing CLOSE;

ods html3 style=sasweb;

options center;

put "Daily market prices and returns";

TITLE1 "excehange rate fluctuations %SYSFUNC(putn(&LastDate_FT, DDMMYY10.))";

FOOTNOTE;

run;

proc report data=WORK.DELTAREPORTNAMES nowd;

column ReportName Delta cv1;

define ReportName / group " " format=$20. missing order=formatted;

compute ReportName;

if ReportName ne " " then hold1=ReportName;

if ReportName eq " " then ReportName=hold1;

endcomp;

define Delta / group missing noprint;

define cv1 / computed "delta(%)" missing FORMAT=COMMAX20.2;

compute cv1;

if Delta ne . then hold2=Delta;

cv1=hold2;

endcomp;

quit;

ODS HTML CLOSE;

ods listing;

RUN;

Best, Joe.

Re: Help concerning mail generated from SAS

data_null__ — Tue, 03 Dec 2013 11:25:03 GMT

If you want to e-mail the report created by PROC REPORT you will need to create it in a file and attach the file to the e-mail.

SAS(R) 9.4 Statements: Reference

Re: Help concerning mail generated from SAS

JoeBill — Tue, 03 Dec 2013 12:10:14 GMT

So there is no way to get a table in a mail generated from SAS 9.3? Of course I can generate the table in a seperate step and attach it, but for layout-purposes I would really appreciate if the table could be a part of the mail.

What if I generated the table by PROC SQL instead?

Re: Help concerning mail generated from SAS

data_null__ — Tue, 03 Dec 2013 12:35:28 GMT

The file(s) created by ODS HTML.

Re: Help concerning mail generated from SAS

Quentin — Tue, 03 Dec 2013 14:15:23 GMT

As you currently have it the DATA _NULL_ step sends an email when it executes, and that happens before the table is produced by your PROC REPORT step.

What you want is the table in the body of the email, correct?

One way you can do this is to run the PROC REPORT step first, and write the results to an html file.

Then in your data step which sends the email, read that file. Soemthing like (untested):

data _null_;
  file outbox ;

  infile MyHTMLoutput ;  *may need to set lrecl;
  input ;
  put _infile_ ;
run;

Above assumes to= subject= etc are all defined in the filename statement for outbox.

I have done that before when I wanted to add text to the message. But if you want to send just the html produced by ODS, would think you could do it with something like:

ods html3 style=sasweb file=outbox;

*PROC REPORT here;

ods html3 close;

HTH,

--Q.

Re: Help concerning mail generated from SAS

JoeBill — Wed, 04 Dec 2013 14:48:40 GMT

Well, the code works great now, and in SAS it generates the HTML output as I expect. However, in Outlook the HTML output is only in plain text/HTML code, and not the table from SAS. Do any of you have an idea about, what is wrong? I do not seem to be able to find an explanation or a solution anywhere... :smileyplain:..

Re: Help concerning mail generated from SAS

data_null__ — Wed, 04 Dec 2013 15:43:05 GMT

JoeBill wrote:

Well, the code works great now,..

what code?

Re: Help concerning mail generated from SAS

JoeBill — Thu, 05 Dec 2013 10:24:47 GMT

The code Quentin offered. However, outlook only displays the plain HTML code. Any clue of why that is?

Re: Help concerning mail generated from SAS

data_null__ — Thu, 05 Dec 2013 11:45:17 GMT

This first example is from the SAS online help for the FILENAME EMAIL statement. It sends me an HTML formatted report in the email text.

filename outbox email
   to='me@myplace.com'
   type='text/html'
   subject='Temperature Conversions'; 
data temperatures;
   do centigrade = -40 to 100 by 10; 
      fahrenheit = centigrade*9/5+32; 
      output; 
      end; 
   run; 
ods html
   body=outbox /* Mail it! */
   rs=none; 
title 'Centigrade to Fahrenheit Conversion Table'; 
proc print; 
   id centigrade;
   var fahrenheit;
   run; 
ods html close;

This next example I wrote to send an html as an attachment.  There are similar examples here and I think these examples cover everthing you need to know about how to e-mail using SAS.

http://support.sas.com/documentation/cdl/en/lestmtsref/63323/HTML/default/viewer.htm#n0ig2krarrz6vtn1aw9zzvtez4qo.htm

You could expand this example to send e-mail to a list of recipients the same attachment of different using a data set as input with address and filename to attach.  If you use this you need to read the documentation on how !EM_SEND! and !EM_ABORT! interact.  In my example I did not need either but I think you will if you send mail to a list using a data set.

ods html file='~/class.html'; 
proc print data=sashelp.class;
   run; 
ods html close; 


data _null_; 
   filevar = 'me@myplace.com'; 
   file dummy email filevar=filevar;
   put '!em_subject! email with attachment'; 
   put '!em_attach! ~/class.html'; 
   put 'Please see attached report'; 
   put '!em_send!'; 
   put '!em_abort!'; 
   run; 

Re: Help concerning mail generated from SAS

BuckeyeSasquatch — Thu, 05 Dec 2013 14:26:56 GMT

Does including the following e-mail option help?

ct="text/html"

Re: Help concerning mail generated from SAS

rocky1983 — Sun, 08 Dec 2013 14:51:00 GMT

Hi,

I had a g8t time in exploring option of sending mail from SAS. See I wanted to send mail which had content in body and table attached to it. I first tried sending from data null then sending table content did not work. When I moved to using proc report. all i was able to do was send table but I was not able to write content first then send have table.

So I tried different approach:

I first created table and stored content in macro variable. and then under data null use html to send content...

Re: Help concerning mail generated from SAS

SteveNZ — Sun, 08 Dec 2013 21:16:15 GMT

Here's the code I use and it works perfectly fine in Outlook:

ods _all_ close;

filename mymail email from="YOUREMAIL@SOMEWHERE.COM"

to="RECIPIENT@SOMEWHERE.COM"

cc="CC_IF_REQUIRED@SOMEWHERE.COM"

subject="Your E-mails Title"

content_type="text/html";

ods msoffice2k file=mymail

style = sasweb ;

*proc report code below...;

proc report data = .....

run ;

ods msoffice2k close;

Re: Help concerning mail generated from SAS

JoeBill — Mon, 09 Dec 2013 09:28:16 GMT

Thanks guys!

Great help! It works perfectly fine now, and the HTML output is looking great in the mail!

Thanks again!