topic Adding rows by condition in SAS Procedures

Adding rows by condition

silasskovsbo — Sun, 30 Mar 2014 16:03:29 GMT

I have a data set(call DATASET) as this (about 100000 observations):

X	Y	Z
a	j	0
b	k	1
c	l	0
d	m	0
e	o	1
f	p	0
g	q	0
h	r	0
i	s	1

I would like to do is to add one blank row above each row where Z=1.

to get this data set

X	Y	Z
a	j	0

b	k	1
c	l	0
d	m	0

e	o	1
f	p	0
g	q	0
h	r	0

i	s	1

Can anybody help and I would be very thankfull.

Best Silas, London

Re: Adding rows by condition

Jagadishkatam — Sun, 30 Mar 2014 16:47:30 GMT

Please try,

data have;

infile cards truncover;

input x :$1. y:$1. z;

cards;

a j 0

b k 1

c l 0

d m 0

e o 1

f p 0

g q 0

h r 0

i s 1

;

proc sort data=have;

by x y;

run;

data want;

set have;

output;

by x y;

if z=1 then output;

run;

data want_;

set want;

by x y;

if first.x and z=1 then call missing(x,y,z);

run;

Thanks,

Jag

Re: Adding rows by condition

pradeepalankar — Sun, 30 Mar 2014 18:46:55 GMT

data have;

input x $ y $ z;

id+1;

cards;

a j 0

b k 1

c l 0

d m 0

e o 1

f p 0

g q 0

h r 0

i s 1

;

proc sort data=have;by descending id;run;

data have;

set have(drop=id);

if z=1 then do; idnew+1;output;

call missing(x,y,z);end;

else;idnew+1;output;

run;

proc sort data=have out=want(drop=idnew);by descending idnew;

run;

Re: Adding rows by condition

Haikuo — Mon, 31 Mar 2014 01:15:38 GMT

A typical look-ahead:

data have;

infile cards truncover;

input x :$1. y:$1. z;

cards;

a j 0

b k 1

c l 0

d m 0

e o 1

f p 0

g q 0

h r 0

i s 1

;

data want;

set have;

set have(firstobs=2 rename=(z=_z) keep=z) have (obs=1 drop=_all_);

output;

if _z=1 then do; call missing (of _all_); output;end;

drop _z;

run;

Haikuo