topic Re: Cannot proc summary output by date in SAS Procedures

Cannot proc summary output by date

shorty_tallz — Thu, 29 Sep 2011 19:06:18 GMT

Hello world,

I'm currently trying output a summary of an existing dataset into a new file (containing only only the summary values). I've tried using the class specifier to summarize (mean, sum, etc.) each variable by date, but after checking the output file, I noticed it still retained each original observation instead of summarizing by date. Thanks in advance for any help!

-John

Here's my code (mtsudat library is already referenced):

proc summary data = sasuser.marchflights maxdec=2 sum mean;

class date;

var distance mail freight boarded transferred nonrevenue passengercapacity;

output out = mtsudat.marchflights;

run;

Cannot proc summary output by date

OS2Rules — Thu, 29 Sep 2011 19:13:50 GMT

Try:

proc summary data = sasuser.marchflights maxdec=2 sum mean;

class date;

var distance mail freight boarded transferred nonrevenue passengercapacity;

output out = mtsudat.marchflights (drop=_TYPE_ _FREQ_) SUM=;

run;

Re: Cannot proc summary output by date

DLing — Thu, 29 Sep 2011 20:16:55 GMT

proc summary data=sasuser.marchflights missing; *--- missing option outputs missing class values as well;

class date; *--- you can attach formats to dates to get monthly, qtrly summaries easily;

var x1 x2 x3;

output out=mtsudat.marchflightsummary(drop=_:) /* drop _type_ _freq_ */

sum=x1sum x2sum x3sum

n=x1n x2n x3n

std(x1)=x1std

;

run;

proc summary by default prints nothing, so maxdec=2 has no effect, nor does the mean option. They are meaningful for PROC MEANS printed output.

Re: Cannot proc summary output by date

Ksharp — Fri, 30 Sep 2011 06:31:03 GMT

You should use nway option and define the sum mean ... at output statement.

proc means noprint data=sashelp.class maxdec=2 sum mean nway;
 class sex;
 var weight height;
 output out=want sum= mean= /autoname;
run;

Ksharp